How to plot a certain surface? What is its parametric equation?

Question

The surface show below is very beautiful; however, I don't know its function either as an implicit function or in parametric form.

Anyone have an idea about it and how to draw it with Mathematica?

One way might be to browse on-line the Mathematica GUIDE book for graphics by Trott at google booksbooks.google.com/… If anyone done something like the above, it will be in that book. Many more amazing plots there. — Nov 24 '13 at 9:15
Do you have any affiliation with this? translate.google.com/… — Nov 24 '13 at 16:45
Can you please give an answer to @belisarius. You have had 4 days to respond and you are back here again today. — Nov 28 '13 at 1:07
@belisarius I have no access to this due to the network being blocked — Nov 28 '13 at 1:48
Strange ... at least @MikeHoneychurch, four others and me aren't suffering any blocking. Someone is playing dirty with your network access. — Nov 28 '13 at 1:51

score 37 · Accepted Answer · Nov 25 '13 at 6:27

Consider this:

ParametricPlot3D[ RotationTransform[a, {0, 1, 0}][{0, 0, Sin[3 a] + 5/4}], {a, 0, 2 Pi}, Evaluated -> True]

Now rotate this around a circle, while rotating it at the same time around its' origin:

ParametricPlot3D[ RotationTransform[b, {0, 0, 1}][{6, 0, 0} + RotationTransform[a + 3 b, {0, 1, 0}][{0, 0, Sin[3 a] + 5/4}]], {a, 0, 2 Pi}, {b, 0, 2 Pi}, PlotPoints -> 40, Evaluated -> True]

EDIT:

A color function, omitting surface mesh, fixing direction of rotation and adding a hint of transparency, like the original:

ParametricPlot3D[ RotationTransform[b, {0, 0, 1}][{6, 0, 0} + RotationTransform[a - 3 b + Pi, {0, 1, 0}][{0, 0, Sin[3 a] + 5/4}]], {a, 0, 2 Pi}, {b, 0, 2 Pi}, PlotPoints -> 40, ColorFunction -> (RGBColor[#, 0, 1 - #, 4/5] &[1/2 + {1, -1}.{#1, #2}/2] &), Mesh -> False, Evaluated -> True]

This might be slightly more intuitive way to write ColorFunction using Blend and Opacity in PlotStyle:

ParametricPlot3D[ RotationTransform[b, {0, 0, 1}][{6, 0, 0} + RotationTransform[a - 3 b + Pi, {0, 1, 0}][{0, 0, Sin[3 a] + 5/4}]], {a, 0, 2 Pi}, {b, 0, 2 Pi}, PlotPoints -> 40, PlotStyle -> Opacity[4/5], ColorFunction -> (Blend[{Red, Blue}, 1/2 + {1, -1}.{#1, #2}/2] &), Mesh -> False, Evaluated -> True]

@SimonWoods Now we just need to figure out how to Abs[] them for a rep boost :D — Nov 24 '13 at 15:07

score 12 · Answer 2 · Nov 25 '13 at 1:16

up vote 12 down vote accept

I'm adding this answer to put on record an answer to the second part the question, "what is the parametric equation?".

The parametric equation is implicit in Kirma's RotationTransform expression. To extract it, one need simply write something like

Clear[a, b] quoit[a_, b_] := Evaluate @ RotationTransform[b, {0, 0, 1}][{6, 0, 0} + RotationTransform[a - 3 b + Pi, {0, 1, 0}][{0, 0, Sin[3 a] + 5/4}]]

The function defined by the above expression, looks like this

Definition @ quoit

quoit[a_, b_] := { Cos[b] (6 - (5/4 + Sin[3 a]) Sin[a - 3 b]), (6 - (5/4 + Sin[3 a]) Sin[a - 3 b]) Sin[b], -Cos[a - 3 b] (5/4 + Sin[3 a]) }

edited Nov 25 '13 at 1:16

answered Nov 24 '13 at 15:11

m_goldberg
12.7k 4 16 53

thank you very much ! very useful – LCFactorization Nov 24 '13 at 15:47

Indeed; maybe I left this part a bit too much implied. – kirma Nov 24 '13 at 17:23

2

up voted

Also the order of wrapping rotation matrix is critical. When the foil rotates around the circle (outmost transform function), the Z axis is fixed. While it spins about its center, the attached Z axis changes direction. Thats why the transform with {0,1,0} is inside the first transform. – Shenghui Nov 25 '13 at 2:16

add comment

如何绘制一种优美曲面,并给出它的参数方程

How to plot a certain surface? What is its parametric equation?

2 Answers

你可能感兴趣的:(stack,Exchange,几何,教学,Mathematica,plot)