Linux三剑客之gawk

awk

文本报告生成器格式化文本输出

有多种版本：New awk（nawk），GNU awk（ gawk）

gawk：模式扫描和处理语言

awk 程序通常由：BEGIN语句块、能够使用模式匹配的通用语句块、END语句块，共3部分组成

用法

• awk [options] ‘program’ var=value file...
• awk [options] -f programfile var=value file…
• awk [options] 'BEGIN{ action;… } pattern{ action;… } END{ action;… }' file ...

选项：

• -F 指明输入时用到的字段分隔符
• -v var=value: 自定义变量

awk执行时由分隔符分隔的字段（域）标记$1,$2..$n称为域标识。

$0为所有域，注意：和shell中变量$符含义不同

文件的每一行称为记录

• BEGIN语句块在awk开始从输入流中读取行之前被执行，这是一个可选的语句块，比如变量初始化、打印输出表格的表头等语句通常可以写在BEGIN语句块中

• END语句块在awk从输入流中读取完所有的行之后即被执行，比如打印所有行的分析结果这类信息汇总都是在END语句块中完成，它也是一个可选语句块

• pattern语句块中的通用命令是最重要的部分，也是可选的。如果没有提供pattern语句块，则默认执行{ print }，即打印每一个读取到的行，awk读取的每一行都会执行该语句块

---

print格式：print item1, item2, ...

注意：

• 输出的各item可以字符串，也可以是数值；当前记录的字段、变量或awk的表达式
• 如省略item，相当于print $0

awk变量使用

FS:输入字段分隔符,默认为空白字符\

OFS:输出字段分隔符,默认为空白字符

awk -v FS=':' '{print $1FS$3}' /etc/passwd

awk -F: '{print $1,$3,$7}’ /etc/passwd

awk -v FS=‘:’ -v OFS=‘:’ '{print $1,$3,$7}’ /etc/passwd

df | grep "/dev/sda" | awk -F" " '{print $1,$5}'

RS:输入记录分隔符，默认为换行符
ORS:输出记录分隔符，默认为换行符

awk -v RS=' ' ‘{print }’ /etc/passwd

awk -v RS=' ' -v ORS='###'‘{print }’ /etc/passwd

NF:字段数量 $(NF-1)
NR:记录号 $(NR-1)

awk -F： ‘{print NF}’ /etc/fstab,引用内置变量不用$

awk -F: '{print $(NF-1)}' /etc/passwd

ls /media/cdrom/Packages/* | awk -F. '{print $(NF-1)}'| sort |uniq -c

FNR：各文件分别计数,记录号

awk '{print FNR}' /etc/fstab /etc/inittab

FILENAME：当前文件名

awk '{print FILENAME}’ /etc/fstab

ARGC：命令行参数的个数

awk '{print ARGC}’ /etc/fstab /etc/inittab

awk ‘BEGIN {print ARGC}’ /etc/fstab /etc/inittab

ARGV：数组，保存的是命令行所给定的各参数

awk ‘BEGIN {print ARGV[0]}’ ****/etc/fstab /etc/inittab

awk ‘BEGIN {print ARGV[1]}’ /etc/fstab /etc/inittab

awk '{print ARGV[0]}' /etc/fstab /etc/inittab

awk变量

自定义变量(区分字符大小写)

• -v var=value
• 在program中直接定义

awk -v var1="hello awk" 'BEGIN{print var1}'

awk -F: '{var1="name";print var1,$1}' /etc/passwd

awk -F: -v OFS=' ' '{var1="name";print var1,FS,$1}' /etc/passwd

[root@centos6 ~]$cat f1

{print script,$1,$2}

[root@centos6 ~]$awk -F: -f f1 script="awk" /etc/passwd

---

printf命令

格式化输出：printf “FORMAT”, item1, item2, ...

• 必须指定FORMAT
• 不会自动换行，需要显式给出换行控制符，\n
• FORMAT中需要分别为后面每个item指定格式符

格式符：与item一一对应

• %c: 显示字符的ASCII码

• %d, %i: 显示十进制整数

• %e, %E:显示科学计数法数值

• %f：显示为浮点数

• %g, %G：以科学计数法或浮点形式显示数值

• %s：显示字符串

• %u：无符号整数

• %%: 显示%自身

修饰符：

• [.#]：第一个数字控制显示的宽度；第二个#表示小数点后精度，%3.1f

• -: 左对齐 （默认右对齐） %-15s

• +：显示数值的正负符号 %+d

awk -F: '{pawk -F: '{printf "%s\n",$1}' /etc/passwd

awk -F: '{printf "%-20s:%10d\n",$1,$3}' /etc/passwd

awk -F: 'BEGIN{printf "user uid\n-----------------------\n"}{printf "%-10s:%10d\n",$1,$3}' /etc/passwd

注意

• 用awk的时候，第一个%，表示的是第一个变量，第二个%表示的是第二个变量

awk -F: '{printf "Username:%s,UID;%d\n",$1,$3}' /etc/passwd

awk '{print "hello awk++"}' /etc/fstab

awk -F: '{print}' /etc/passwd

awk -F: '{print "jiang"}' /etc/passwd

awk -F: '{print $1"\t"$3}' /etc/passwd

awk -F: '{print $1" "$3}' /etc/passwd

awk -F: ‘{printf “Username: %s,UID:%d\n",$1,$3}’ /etc/passwd

awk -F: '{printf "Username %-15s UID:%d\n",$1,$3}' /etc/passwd

awk -F: ‘{printf "Username: %-15s,UID:%d\n",$1,$3}’ /etc/passwd

awk 'BEGIN{print 2^10}'

awk 'BEGIN{print "hello world"}'

操作符

比较操作符

==, !=, >, >=, <, <=

[root@centos6 ~]$awk 'BEGIN{i=0;print ++i,i}'
1 1
[root@centos6 ~]$awk 'BEGIN{i=0;print i++,i}' 
0 1

模式匹配符：
~：左边是否和右边匹配包含

!~：是否不匹配

awk -F: '$0 !~ /^root/{print $1}' /etc/passwd

awk '$0 !~ "^root"' /etc/passwd

awk -F: '$3==0' /etc/passwd

df | awk '/^\/dev\/sda/{print $1,$5}'

df |awk -F% '/^\/dev\/sd/{print $1,$5}'|awk '$5>=2{print $1,$5}'

逻辑操作符

与&&，或||，非!

awk –F: '$3>=0 && $3<=1000 {print $1}' /etc/passwd

awk -F: '$3==0 || $3>=1000 {print $1}' /etc/passwd

awk -F: ‘!($3==0) {print $1}' /etc/passwd

awk -F: ‘!($3>=500) {print $3}’ /etc/passwd

条件表达式（三目表达式）：

selector?if-true-expression:if-false-expression

[root@centos6 ~]$awk -F: '{$3>=400?usertype="Common User":usertype="Sysadmin or SysUser";printf "%15s:%-s\n",$1,usertype}' /etc/passwd 
           root:Sysadmin or SysUser
            bin:Sysadmin or SysUser
         daemon:Sysadmin or SysUser
            adm:Sysadmin or SysUser
             lp:Sysadmin or SysUser
           sync:Sysadmin or SysUser
       shutdown:Sysadmin or SysUser
           halt:Sysadmin or SysUser
           mail:Sysadmin or SysUser
           uucp:Sysadmin or SysUser
       operator:Sysadmin or SysUser
          games:Sysadmin or SysUser
         gopher:Sysadmin or SysUser
            ftp:Sysadmin or SysUser
         nobody:Sysadmin or SysUser
           vcsa:Sysadmin or SysUser
       saslauth:Common User
        postfix:Sysadmin or SysUser
           sshd:Sysadmin or SysUser
            ntp:Sysadmin or SysUser
          jiang:Common User

awk的取反返回值

[root@centos6 ~]$awk 'BEGIN{i=0;print !i}'
1    
[root@centos6 ~]$awk 'BEGIN{i=2;print !i}'
0    
[root@centos6 ~]$awk 'BEGIN{i="";print !i}' 
1
[root@centos6 ~]$awk 'BEGIN{i="abcd";print !i}'
0
[root@centos6 ~]$awk 'BEGIN{print !i}'         
1

• 0取反为1
• 非0取反为0
• 空值取反为1
• 有值取反为0
• 无值取反为1

在awk里:有值 或 非0 为真

[root@centos74 ~]#awk -F: 'i=""{print $1,$3}' /etc/passwd  
[root@centos74 ~]#awk -F: 'i="abc"{print $1,$3}' /etc/passwd 
root 0
bin 1
daemon 2
...

[root@centos74 ~]#awk -F: '!i=0{print $1,$3}' /etc/passwd    
[root@centos74 ~]#awk -F: '!(i=0){print $1,$3}' /etc/passwd
root 0
bin 1
daemon 2
...

awk的PATTERN

awk '!/^UUID/{print $0}' /etc/fstab

awk -F: ‘/^root>/,/nobody>/{print $1}' /etc/passwd

awk -F: ‘(NR>=10&&NR<=20){print NR,$1}' /etc/passwd

awk -F : 'BEGIN {print "USER USERID"} {print $1":"$3} END{print "end file"}' /etc/passwd

awk -F: '{print "USER USERUID"; print $1,$3}END{print "end file"}' /etc/passwd

用awk打印奇数行和偶数行

[root@centos6 ~]$seq 10 |awk 'i=!(!i)'
[root@centos6 ~]$seq 10 |awk 'i=!i'    
1
3
5
7
9
[root@centos6 ~]$seq 10 |awk '!(i=!i)'
2
4
6
8
10

---

awk控制语句

if-else

语法

 if(condition){statement;…}[else statement]
if(condition1){statement1}elseif(condition2){statement2}else{statement3}

使用场景：对awk取得的整行或某个字段做条件判断

awk -F: '{if($3>=1000)print $1,$3}' /etc/passwd
awk -F: '{if($NF=="/bin/bash") print $1}' /etc/passwd
awk '{if(NF>5) print $0}' /etc/fstab
awk -F: '{if($3>=1000) {printf "Common user: %s\n",$1} else {printf "root or Sysuser: %s\n",$1}}' /etc/passwd
awk -F: '{if($3>=1000) printf "Common user: %s\n",$1; else printf "root or Sysuser: %s\n",$1}' /etc/passwd
df -h|awk -F% '/^\/dev/{print $1}'|awk '$NF>=80{print $1,$5}‘
awk 'BEGIN{ test=100;if(test>90){print "very good“}else if(test>60){ print "good"}else{print "no pass"}}''

while循环

while(condition){statement;…}

使用场景：

• 条件“真”，进入循环；条件“假”，退出循环
• 对一行内的多个字段逐一类似处理时使用
• 对数组中的各元素逐一处理时使

awk 'BEGIN{print length("aaddbb")}'----->统计有多少个字符

awk '/^[[:space:]]*linux16/{i=1;while(i<=NF){print $i,length($i); i++}}' /etc/grub2.cfg
awk ‘/^[[:space:]]*linux16/{i=1;while(i<=NF) {if(length($i)>=10) {print $i,length($i)}; i++}}’ /etc/grub2.cfg

do-while循环

语法：do {statement;…}while(condition)
意义：无论真假，至少执行一次循环体

awk 'BEGIN{ total=0;i=0;do{ total+=i;i++;}while(i<=100);print total}’

for循环

语法：for(expr1;expr2;expr3) {statement;…}
特殊用法：能够遍历数组中的元素
语法：for(var in array) {for-body}

awk '/^[[:space:]]*linux16/{for(i=1;i<=NF;i++) {print $i,length($i)}}' /etc/grub2.cfg

性能比较

• time (awk 'BEGIN{ total=0;for(i=0;i<=10000;i++){total+=i;};print total;}')
• time(total=0;for i in {1..10000};do total=$(($total+i));done;echo $total)
• time(for ((i=0;i<=10000;i++));do let total+=i;done;echo $total)
• time(seq –s ”+” 10000|bc)

switch语句
语法：
switch(expression) {case VALUE1 or /REGEXP/: statement1; case VALUE2 or /REGEXP2/: statement2; ...; default: statementn}

break和continue
break [n]
continue [n]
awk ‘BEGIN{sum=0;for(i=1;i<=100;i++){if(i%2==0)continue;sum+=i}print sum}'

awk ‘BEGIN{sum=0;for(i=1;i<=100;i++){if(i==66)break;sum+=i}print sum}‘

[root@centos6 ~]$awk 'BEGIN{sum=0;for(i=1;i<=100;i++){if(i%2==1)break;sum+=i}print sum}'        
0
[root@centos6 ~]$awk 'BEGIN{sum=0;for(i=1;i<=100;i++){if(i%2==0)break;sum+=i}print sum}' 
1

next:

提前结束对本行处理而直接进入下一行处理（awk自身循环）

• awk -F: '{if($3%2!=0) next; print $1,$3}' /etc/passwd

注意

• awk -F: '{if($3>10)print $1,$3;if($3<400)print $1,$3}' /etc/passwd------->是or关系
• awk -F: '{if($3>10 && $3<400)print $1,$3}' /etc/passwd----->是and关系

awk数组
index-expression:

• 可使用任意字符串；字符串要使用双引号括起来
• 如果某数组元素事先不存在，在引用时，awk会自动创建此元素，并将其值初始化为“空串”
• 若要判断数组中是否存在某元素，要使用“index in array”格式进行遍历

weekdays[“mon”]="Monday“
•awk 'BEGIN{weekdays["mon"]="Monday";
weekdays["tue"]="Tuesday";print weekdays["mon"]}‘
awk ‘!arr[$0]++’ dupfile
    !arr[$0]++ <------> !arr[$0]++:是以文件的整行为下标，文件每行的下标的元
    素值为空，空取反为1，所以打印该行。但++是对这个下标的元素值加1，空加1值为1
awk '{!arr[$0]++;print $0, arr[$0]}' dupfile

若要遍历数组中的每个元素，要使用for循环

for(var in array) {for-body}
注意：var会遍历array的每个索引

awk 'BEGIN{weekdays["mon"]="Monday";weekdays["tue"]="Tuesday";for(i in weekdays) {print weekdays[i]}}'

netstat -tan | awk '/^tcp/{state[$NF]++}END{for(i in state) { print i,state[i]}}'

awk '{ip[$1]++}END{for(i in ip) {print i,ip[i]}}' /var/log/httpd/access_log

[root@centos74 ~]#netstat -tan
Active Internet connections (servers and established)
Proto Recv-Q Send-Q Local Address           Foreign Address         State      
tcp        0      0 0.0.0.0:22              0.0.0.0:*               LISTEN     
tcp        0      0 127.0.0.1:25            0.0.0.0:*               LISTEN     
tcp        0      0 192.168.30.222:22       192.168.30.1:49540      ESTABLISHED
tcp6       0      0 :::22                   :::*                    LISTEN     
tcp6       0      0 ::1:25                  :::*                    LISTEN     
[root@centos74 ~]#netstat -tan | awk '/^tcp/{state[$NF]++}END{for(i in state) { print i,state[i]}}'
LISTEN 4
ESTABLISHED 1

awk函数
数值处理：
rand()：返回0和1之间一个随机数
awk 'BEGIN{srand();for(i=0;i<10;i++)prnt int(rand()100)}'
字符串处理：
length([s])：返回指定字符串的长度
sub(r,s,[t])：对t字符串进行搜索r表示的模式匹配的内容，并将第一个匹配的内容替换为s
echo "2008:08:08 08:08:08" | awk 'sub(/:/,“-",$1)'
gsub(r,s,[t])：对t字符串进行搜索r表示的模式匹配的内容，并全部替换为s所表示的内容
echo "2008:08:08 08:08:08" | awk ‘gsub(/:/,“-",$0)'
split(s,array,[r])：以r为分隔符，切割字符串s，并将切割后的结果保存至array所表示的数组中，第一个索引值为1,第二个索引值为2,…
netstat -tan | awk '/^tcp>/{split($5,ip,":");count[ip[1]]++}END{for (i in count) {print i,count[i]}}'

自定义函数
格式：

function name ( parameter, parameter, ... ) {
statements
return expression
}

示例
cat fun.awk
function max(v1,v2) {
v1>v2?var=v1:var=v2
return var
}
BEGIN{a=3;b=2;print max(a,b)}
awk –f fun.awk

[root@centos74 ~]#cat fun.awk 
function max(v1,v2){
      v1>v2?var=v1:var=v2
      return var
}
BEGIN{print max(a,b)}
[root@centos74 ~]#awk -v a=30 -v b=4660 -f fun.awk
4660

awk中调用shell命令
system命令
空格是awk中的字符串连接符，如果system中需要使用awk中的变量可以使用空格分隔，或者说除了awk的变量外其他一律用""引用起来。
awk BEGIN'{system("hostname") }'
awk 'BEGIN{score=100; system("echo your score is " score) }'

awk的脚本
将awk程序写成脚本，直接调用或执行

cat f1.awk
   {if($3>=1000)print $1,$3}
awk -F: -f f1.awk /etc/passwd

-----------------------------

cat f2.awk
    #!/bin/awk –f
    #this is a awk script
    {if($3>=1000)print $1,$3}
    chmod +x f2.awk
f2.awk –F: /etc/passwd

向awk脚本传递参数

awkfile var=value var2=value2... Inputfile

注意：在BEGIN过程中不可用。直到首行输入完成以后，变量才可用。可以通过-v 参数，让awk在执行BEGIN之前得到变量的值。命令行中每一个指定的变量都需要一个-v参数

cat test.awk
#!/bin/awk –f
{if($3 >=min && $3<=max)print $1,$3}
chmod +x test.awk
test.awk -F: min=100 max=200 /etc/passwd