地球空间数据交换格式
|
中华人民共和国国家标准
地球空间数据交换格式 Geo-spatial data transfer format |
|
|
|
目 次
前言
.......................................................................... 1 范围 ....................................................................... 2 引用标准 ................................................................... 3 术语 ........................................................................ 4 总则 ........................................................................ 5 矢量数据交换格式 ........................................................... 6 影象数据交换格式 ............................................................ 7 格网数据交换格式 ............................................................ 附录 A（标准的附录）空间数据的概念模型的对象定义 .............................. 附录Ｂ（提示的附录）矢量数据交换格式样本 ..................................... 附录Ｃ（提示的附录）影像数据交换格式样本 ..................................... 附录Ｄ（提示的附录）格网数据交换格式样本 ...................................... |
1 范围
本标准规定了矢量和栅格两种空间数据的交换格式。适用于多种矢量数据、影像数据和格网 GIS数据以及数字高程模型（ DEM）等的数据交换。本标准不包括元数据的交换格式。
2 引用标准
下列标准所包含的条文，通过在本标准中引用而成为本标准的条文。本标准出版时，所示版本均为有效。所有标准都会被修订，使用本标准的各方应探讨使用下列标准最新版本的可能性。
GB2312-80 信息交换用汉字编码字符集、基本集
3 术语
3.1 实体 entity
1． 概念模式中数据元素集合的表示。
2． 具共同性质的对象类。
3.2 实样 instance
地理要素及描述该地理要素特性的信息。
3.3 节点 node
零维拓扑原素。
3.4 边 edge
一维拓扑原素。
3.5 面 face
二维拓扑原素。
3.6 拓扑关系 topologic relationship
描述两个要素之间边界拓扑和点集拓扑的要素关系。
3.7 拓扑 topology
对相连或相邻的点、线、面体之间关系的科学阐述。特指那种在连续映射变换下保持不变的对象性质。
3.8 要素 feature
真实世界现象的抽象。
3.9 元数据 metadata
关于数据的内容、质量、状况和其它特性的描述性数据。
3.10 栅格数据 raster data
被表示成有规则的空间阵列的数据
3.11 矢量数据 vector data
由几何原素所表示的数据。
3.12 格网数据 grid data
与特定参照系相对应的空间的规则化棋盘状布置。
4 总则
4.1 本标准规定的空间数据交换格式的基础是一个空间数据模型。其概念模型和空间对象的定义见
附录 A（标准的附录）。
4.2 本标准采用 Backus-Naur格式 (BNF)来精确描述所说明的结构、相互关系和格式。每一产生规则都有一个左项 (标识 )和一个右项 (表达式 ),其间由 “::=”连接 ,含义是左项由右项产生或左项被右项取代。
4.3 用于产生规则的符号所具有的意义见表１。
本标准规定了矢量和栅格两种空间数据的交换格式。适用于多种矢量数据、影像数据和格网 GIS数据以及数字高程模型（ DEM）等的数据交换。本标准不包括元数据的交换格式。
2 引用标准
下列标准所包含的条文，通过在本标准中引用而成为本标准的条文。本标准出版时，所示版本均为有效。所有标准都会被修订，使用本标准的各方应探讨使用下列标准最新版本的可能性。
GB2312-80 信息交换用汉字编码字符集、基本集
3 术语
3.1 实体 entity
1． 概念模式中数据元素集合的表示。
2． 具共同性质的对象类。
3.2 实样 instance
地理要素及描述该地理要素特性的信息。
3.3 节点 node
零维拓扑原素。
3.4 边 edge
一维拓扑原素。
3.5 面 face
二维拓扑原素。
3.6 拓扑关系 topologic relationship
描述两个要素之间边界拓扑和点集拓扑的要素关系。
3.7 拓扑 topology
对相连或相邻的点、线、面体之间关系的科学阐述。特指那种在连续映射变换下保持不变的对象性质。
3.8 要素 feature
真实世界现象的抽象。
3.9 元数据 metadata
关于数据的内容、质量、状况和其它特性的描述性数据。
3.10 栅格数据 raster data
被表示成有规则的空间阵列的数据
3.11 矢量数据 vector data
由几何原素所表示的数据。
3.12 格网数据 grid data
与特定参照系相对应的空间的规则化棋盘状布置。
4 总则
4.1 本标准规定的空间数据交换格式的基础是一个空间数据模型。其概念模型和空间对象的定义见
附录 A（标准的附录）。
4.2 本标准采用 Backus-Naur格式 (BNF)来精确描述所说明的结构、相互关系和格式。每一产生规则都有一个左项 (标识 )和一个右项 (表达式 ),其间由 “::=”连接 ,含义是左项由右项产生或左项被右项取代。
4.3 用于产生规则的符号所具有的意义见表１。
表１
4.4 文件结构中的基本组成元素及其说明
a. <CR> ::= 回车符 (0AH){{<空白符 >}回车符 (0AH)}
表示换行和 /或若干空行。
b. <空白符 > ::= 空格符 (20H) | 制表符 (08H)
c. <目标标识码 > ::= <整数 >
正数用作目标标识 ,零和负数用于表达组成面状要素的线的间隔和方向。
d. <要素类型编码 > ::= {<汉字字符 >|<英文字母 >|<数字 >|_}1
不超过 16个字节。 “Unknown”是预定义的保留编码。
e. <层名 > ::= {<汉字字符 >|<英文字母 >|<数字 >|_}1
不超过 32个字节。 “Unknown”是预定义的保留层名。
f. <X> ::= <浮点 >
X方向坐标。
g. <Y> ::= <浮点 >
Y方向坐标。
h. <Z> ::= <浮点 >
高程坐标，单位是米。
i. <?> ::= <浮点 >
注记方向 , 单位是度。
j. <RGB> ::= <整数 >
用于表达颜色的整数型值。
k. <日期 > ::= <YYYY><MM><DD>
<YYYY>、 <MM>、 <DD>分别表示年月日 ,不足的前面补 “0”。
l. <英文字母 > ::= A～ Z | a～ z
m. <数字 > ::= 0～ 9
n. <汉字字符 >::= 符合 GB2312-80 的所有汉字字符
o. <字符 > ::=!|"|#|$|%|&|'|*|+|,|-|.|/|:|;|<|=|>|?|@|\|^|_|`|
“(”|“)”|“[”|“]”|“{”|“|”|“}”|“~”|<英文字母 >|<数字 >|<汉字字符 >
p. <字符串 > ::= {<字符 >}1
q. <标识符 > ::= <汉字字符 >|<英文字母 >{<汉字字符 >|<英文字母 >|<数字 >|_}
r. <整数 >::= [+|-]{<数字 >}1
在计算机内部运算时应表示为 32位整型数。
s. <浮点 > ::= [+|-]{<数字 >}[.[{<数字 >}]][ E | e <整数 >]
在计算机内部运算时应表示为 64位双精度浮点数。
4.5 本标准规定的交换格式所用的关键字（字典序）见表 2
表2
4.6 本标准包含四种文件类型。分别由数据标志 DataMark予以区别。
4.7 本标准所采用的文件名后缀见表 3。
表3
5 矢量数据交换格式
5.1 一般规定
5.1.1 本格式仅考虑空间对象的零维对象、一维对象和二维对象，并作如下规定：
a.结点包括纯结点和结点要素。规定纯结点的要素类型编码和层名为 “Unknown”。
b.注记参考点和注记参考线放在注记的数据结构中作为注记的一部分进行记录。
c.多边形标识点放在面状要素的数据结构中作为面状要素的一部分进行记录。
d.有向点是点状要素 ,但有两对 XY(Z)坐标。
e.线状要素包括拓扑弧段、无拓扑弧段与线状要素 ,公用一个数据结构。具体说明见 5.4.3.2。
f.规定无属性的要素类型编码和层名为 “Unknown”。
g.本格式可以记录拓扑关系，也可以不记录拓扑关系。程序读符合本标准的交换文件时不应以有无拓扑关系为前提，写符合本标准的交换文件时，可根据原始数据灵活掌握是否记录拓扑关系。
5.1.2 本交换格式的几何图形数据分为点状要素、线状要素、面状要素三类。点状要素有三种 ,分别是独立要素点、结点和有向点。线状要素可以构成更高一级的线状要素。面状要素的边界可以由线状要素构成。面状要素也可以构成更高一级的面状要素。
5.1.3 空间矢量数据由几何图形数据和属性数据组成 ,两者通过目标标识码 (关键字 )连接 ,即具有相同目标标识码的几何图形数据和属性数据是对同一空间对象的描述。任一几何对象采用的属性数据结构可通过在几何对象上添加要素类型编码来说明。
5.1.4 空间矢量数据交换文件由六部分组成 :第一部分为文件头 ,它包含了该文件的基本特征数据 ,如图幅范围、坐标维数、比例尺等；第二部分为要素类型参数；第三部分为属性数据结构；第四部分为几何图形数据；第五部分为注记；第六部分为属性数据。
<矢量数据交换格式 > ::=
<文件头 ><要素类型参数 ><属性数据结构 ><几何图形数据 ><注记 ><属性数据 >
5.1.5 所有数据写在一个文件内 ,第一步采用纯文本格式 ,待条件成熟后增加二进制格式及相关的 API接口规范。
5.1.6 文件中的汉字不做转换 ,直接采用 GB2312-80编码，对 GB2312-80未编码的扩展汉字由读写本交换格式的程序自行决定扩展编码方式、本标准暂不作定义。
5.1.7 除表示属性值和注记内容外 ,字符和字符串的大小写一律不区分。
5.1.8 除对 Varchar型属性字段值的表示外，交换文件中所有空行均应被忽略。
5.2 文件头的描述及其结构
5.2.1 不限定字节数以便扩充 ,采用字符标识说明文件头的起始位置。
5.2.2 文件头分两类数据 :基本的且必须的信息和扩充的附加信息。附加部分可以省略。
5.2.3 文件头内容和格式如下 :
<文件头 > ::= HeadBegin<CR>
DataMark: CNSDTF-VCT<CR>Version: <浮点 ><CR>
Unit: <字符 ><CR>Dim: <整数 ><CR>Topo: <整数 ><CR>
[Coordinate: G|M<CR>]
[Projection: <字符串 ><CR>Spheroid: <字符串 ><CR>Parameters: <字符串 ><CR>]
[MinX: <浮点 ><CR>MinY: <浮点 ><CR>MaxX: <浮点 ><CR>MaxY: <浮点 ><CR>]
[MinZ: <浮点 ><CR>MaxZ: <浮点 ><CR>]
[ScaleM: <整数 ><CR>]
[Date: <日期 ><CR>]
[Separator: <字符 ><CR>]
HeadEnd<CR>
其中 :
DataMark: 中国地球空间数据交换格式 -矢量交换格式 (CNSDTF-VCT)的标志。基本部分，是不可缺省。
Version: 该空间数据交换格式的版本号 ,如 1.0。基本部分，不可缺省。
Unit: 坐标单位 ,K表示公里 ,M表示米 ,D表示以度为单位的经纬度 ,S表示以度分秒表示的经纬度 (此时坐标格式为 DDDMMSS.SSSS, DDD为度 , MM为分 , SS.SSSS为秒 )。基本部分，不可缺省。
Dim: 坐标维数 ,2表示仅有二维坐标 ,3表示有三维坐标。三维时 , 无论 Unit如何定义 ,高程坐标单位均用米。基本部分，不可缺省。
Topo: 是否带结点与线段的拓扑关系。 2表示有结点关联线目标的标识以及线目标有起结点、终结点、左多边形、右多边形的拓扑信息。 1则表示没有这些信息但有多边形关联的线目标标识 ,0表示没有拓扑 ,多边形直接带坐标。基本部分，不可缺省。
Coordinate: 坐标系， G表示测量坐标系、 M表示数学坐标系。基本部分，缺省为 M。
Projection: 投影类型。附加部分。
Spheroid: 参考椭球体。附加部分。
Parameters: 投影参数。根据不同的投影有不同的参数表 ,格式不作严格限定 ,但必须在同一行内表达完毕。附加部分。
MinX: 最小 X。附加部分。
MinY: 最小 Y。附加部分。
MinZ: 最小 Z。附加部分。
MaxX: 最大 X。附加部分。
MaxY: 最大 Y。附加部分。
MaxZ: 最大 Z。附加部分。
ScaleM: 原图比例尺分母。附加部分。
Date: 有效数据时间 (年月 )。附加部分。
Separator: 任意单字节非空白字符 ,用做属性字段分隔符。基本部分，缺省为逗号 (,)。
5.3 要素类型参数
5.3.1 要素类型参数定义之前须加上 “FeatureCodeBegin”,结尾须加上 “FeatureCodeEnd”作为定义要素类型参数的标志 ,中间不再写字符说明。
5.3.2 可以自行定义若干用户项，以保存所使用的软件内部的特殊要素类型参数信息。
5.3.3 <要素类型参数 > ::=
FeatureCodeBegin<CR>
{<要素类型编码 >,<要素类型名称 >,<几何类型 >,<缺省颜色 >,<属性表名 >{,<用户项 >}<CR>}
FeatureCodeEnd<CR>
<要素类型名称 > ::= <字符串 >
<字符串 >中不能含有逗号 (,)。
<几何类型 > ::= Point | Line | Polygon | Annotation
<缺省颜色 > ::= <RGB>
<属性表名 > ::= <标识符 >
<用户项 > ::= <字符串 >
<字符串 >中不能含有逗号 (,)。
5.4 属性数据结构
5.4.1 在每个要素类型定义了基本参数以后 ,紧接着定义它的属性结构。没有属性项的 ,属性项个数为零 ,此时不定义属性字段。
5.4.2 属性数据结构定义之前须加上 “TableStructureBegin”,结尾须加上 “
TableStructureEnd”作为定义属性数据结构的标志 ,中间不再写字符说明。
5.4.3 < 属性数据结构 > ::= TableStructureBegin<CR>{<属性表定义 >}TableStructureEnd<CR>
<属性表定义 > ::= <属性表名 >,<属性项个数 ><CR>{<属性项名 >,<字段描述 ><CR>}
<属性项个数 > ::= <整数 >
<属性项名 > ::= <标识符 >
<字段描述 > ::= Char,<宽度 > | Varchar | Integer[,<宽度 >] | Float[,<宽度 >,<精度 >] |
Boolean | Date | Time | Varbin
由于文本交换格式的限制 ,本格式暂不包含二进制类型字段值的转换。二进制字段 (如多媒体数据 )采取外挂文件转换 ,在字段描述处记录 “Varbin”,字段值处记录外挂文件路径。
<宽度 > ::= <整数 >
<精度 > ::= <整数 >
5.5 几何图形数据
5.5.1 几何图形数据紧接着要素类型参数定义 ,分别用 “PointBegin”、 “PointEnd”、 “
LineBegin”、 “LineEnd”、 “PolygonBegin”、 “PolygonEnd”分开。
5.5.2 点、线、面相对集中地放在一起。点、线、面的几何数据不再附加标志说明。
5.5.3 内容和格式
<几何图形数据 > ::=
PointBegin<CR>{<点状要素 >}PointEnd<CR>
LineBegin<CR>{<线状要素 >}LineEnd<CR>
PolygonBegin<CR>{<面状要素 >}PolygonEnd<CR>
5.5.3 .1 点状要素
<点状要素 > ::=
<目标标识码 ><CR><要素类型编码 ><CR><层名 ><CR><点的特征类型 ><CR>
<X>,<Y>[,<Z>]<CR>[<X>,<Y>[,<Z>]<CR>]
[<关联线对象的个数 >,{<关联线对象的标识码 >}<CR>]
<点的特征类型 > ::= 1|2|3
其中 ,1表示独立点 ,2结点 ,3有向点 ,有向点时有两对 XYZ坐标
<关联线对象的个数 > ::= <整数 >
<关联线对象的标识码 > ::= <目标标识码 >
如果文件头申明 Topo=2,且点的特征类型为 2,则有结点关联的线标识号。
5.5.3 .2 线状要素
<线状要素 > ::=
<目标标识码 ><CR><要素类型编码 ><CR><层名 ><CR><线的特征类型 ><CR>
<线状要素直接坐标 >|<线状要素间接坐标 >
[<起结点号 ><CR><终结点号 ><CR><左多边形 ><CR><右多边形 ><CR>]
<线的特征类型 > ::= 1|2|3|4|5|6|100
1为折线、 2为圆弧、 3圆、 4 为椭圆、 5光滑曲线、 6为 B样条曲线、 100为间接坐标线
<线状要素直接坐标 > ::= <点数 ><CR>{<X>,<Y>[,<Z>]<CR>}
<线的特征类型 >不为 100时 ,采用此记法。
<点数 > ::= <整数 >
圆弧和圆的点数均为 3、椭圆为 4。取点法如下图 ,箭头方向为弧段走向。
<线状要素间接坐标 > ::= <线目标的项数 ><CR>{<线目标标识号 >{,<线目标标识号 >} <CR>}
<线的特征类型 >为 100时 ,采用此记法。
<线目标的项数 > ::= <整数 >
<线目标标识号 > ::= <整数 >
线目标标识号 8个一行 ,逗号 (,)分开 ,总数目为 <线目标的项数 >。
如果文件头中申明 Topo=2,则有以下四项，否则没有。
<起结点号 > ::= <目标标识码 >
<终结点号 > ::= <目标标识码 >
<左多边形 > ::= <目标标识码 >
<右多边形 > ::= <目标标识码 >
5.5.3 .3 面状要素
<面状要素 > ::=
<目标标识码 ><CR><要素类型编码 ><CR><层名 ><CR><labX>,<labY><CR><边界 >
<labX> ::= <浮点 >
<labY> ::= <浮点 >
labX和 labY为标识点坐标。
<边界 > ::= <面状要素间接坐标 >|<面状要素直接坐标 >
如果文件头中申明 Topo=0,则采用直接坐标 ,否则采用间接坐标。
<面状要素间接坐标 > ::= <子目标的项数 ><CR>{<子目标标识号 >{,<子目标标识号 >} <CR>}
<子目标的项数 > ::= <整数 > 项数包括分隔标识。
<子目标标识号 > ::= <线目标标识号 >|<面目标标识号 >
子目标标识号 8个一行，逗号分开 (,)，总数目为 <子目标的项数 >。
<线目标标识号 > ::= <整数 >
<面目标标识号 > ::= <整数 >
若封闭边界由线目标组成，则以 <线目标标识号 >的负值作为线目标反向连接的标识，以 0作为两个封闭边界间的分隔标识，分隔标识计入 <子目标的项数 >中。同一封闭边界不能由线目标和面目标混合组成。
<面状要素直接坐标 > ::= {<点数 ><CR>{<X>,<Y>[,<Z>]<CR>} }1 0<CR> 顺序记录组成的每条封闭边界。各边界采用点数 -坐标串的方式记录。最后用一个独占一行的 0（点数为 0）表示此面状要素数据的结束。 *
5.6 注记
5.6.1 注记紧接着几何图形数据 ,用 “AnnotationBegin”、 “AnnotationEnd”表示开始和结束。
5.6.2 内容和格式
<注记 > ::=
AnnotationBegin<CR>{<注记要素 >}AnnotationEnd<CR>
<注记要素 > ::=
<目标标识码 ><CR><要素类型编码 ><CR><层名 ><CR>
<字体 ><CR><颜色 ><CR><字型 ><CR><大小 ><CR><间隔 ><CR>
<注记内容 ><CR><注记位置点数 ><CR>{<X>,<Y>,<?><CR>}
<字体 > ::= <字符串 >
<颜色 > ::= <RGB>
<字型 > ::= <磅数 >,<形状 >,<下划线 >
<磅数 > ::= <整数 >
0～ 1000的整数 ,表示字型线划的粗细程度。如 400代表正常体 ,700代表粗体字。
<形状 > ::= 0|1|2|3|4|5
0代表正体 ,1代表左斜 ,2代表右斜 ,3代表左耸 ,4代表右耸。
<下划线 > ::= T|F|Y|N
T和 Y代表有下划线 ,F和 N代表没有下划线。
<大小 > ::= <字号 >|<字宽 >,<字高 >
<字号 > ::= <浮点 >
<字宽 > ::= <浮点 >
<字高 > ::= <浮点 >
<间隔 > ::= <浮点 >
<注记内容 > ::= <字符串 >
<注记位置点数 > ::= <整数 >
注记位置点数应为 1(此时是单点注记的情况 )或等于注记内容的字符数 (此时每个字符有独立的位置和方向 )。注意 :由于双字节字符的存在 ,注记内容的字符数一般不等于字节数。
5.7 属性数据格式
5.7.1 所有目标的属性数据块以 “AttributeBegin”和 “AttributeEnd”作为开始和结束的标志 ,每个目标的属性放在一行。
5.7.2 对变长字符串 ,在属性值的位置上填一变长字符串标识 ,实际值在由 “VarcharBegin”和 “VarcharEnd”分隔的数据块中。
5.7.3 每一属性表的属性相对集中 ,由属性表名作为开始标志， “TableEnd” 作为结束标志。
5.7.4 内容和格式
<属性数据 > ::= AttributeBegin<CR>{<属性表 >}AttributeEnd<CR>
[VarcharBegin<CR>{<变长字符串表 >}VarcharEnd<CR>]
<属性表 > ::= <属性表名 ><CR>{<目标标识码 >{<分隔符 ><属性项 >}<CR>}TableEnd<CR>
<分隔符 >::= <字符 >
在文件头中定义的属性字段分隔符。
<属性项 > ::= <字符串 >|<整数 >|<浮点 >|<日期 >|Y|N|T|F|<变长字符串标识 >
类型为字符串的属性项的值 ,字符串中不能含有分隔符 ,可以是空串 (此时两分隔符连续 )。
<变长字符串标识 >::= <整数 >
<变长字符串表 > ::= {<变长字符串标识 ><CR><正文 ><分隔符 ><CR>}
分隔符单独作一行表示该字段值的结束。
<正文 > ::= <字符串 ><CR>{<字符串 ><CR>}
<正文 >中的空行是变长字符串值的一部分，此时 <CR>代表的空行在读取时不应被忽略。
6 影象数据交换格式
6.1 影象数据的交换格式 ,原则上采用国际工业标准无压缩的 TIFF或 BMP等格式，但需将大地坐标在影象上的定位信息以及象素的地面分辨率等信息添加到 TIFF或 BMP等文件上。
6.2 附加的信息用纯文本格式另写一个文件 , 不应破坏原有 TIFF或 BMP等格式。
6.3 附加的信息分两类 :基本的且必须的信息和扩充的附加信息。扩充部分可以省略。
6.4 内容和格式
<影象数据交换格式 > ::= <影象文件 ><附加信息文件 >
<影象文件 > ::= 无压缩的 TIFF文件 |BMP文件 |其它格式的影象文件
<附加信息文件 > ::=
DataMark: CNSDTF-IMG<CR>Version: <浮点 ><CR>
Unit: <字符 ><CR>Type: <字符 ><CR>SaveWay: <字符 ><CR>
Band: <整数 ><CR>Alpha: <浮点 ><CR>Row: <整数 ><CR>Col: <整数 ><CR>
Xr: <浮点 ><CR>Yc: <浮点 ><CR>Dr: <浮点 ><CR>Dc: <浮点 ><CR>
[Coordinate: G|M<CR>]
[Projection: <字符串 ><CR>Spheroid: <字符串 ><CR>Parameters: <字符串 ><CR>]
[MinV: <整数 ><CR>MaxV: <整数 ><CR>]
其中 :
DataMark: 中国地球空间数据交换格式 -影象交换格式 (CNSDTF-IMG)的标志。基本部分，不可缺省。
Version: 该空间数据交换格式的版本号。基本部分，不可缺省。
Unit: 坐标单位 ,M表示米 ,D表示度。基本部分，不可缺省。
Type: 影象类型。基本部分，不可缺省。
SaveWay: 彩色影象采取的存贮方式。 Y表示以象元为间隔排列 , H表示以行为间隔排列 , B表示以波段为间隔排列 , RGB表示 RGB混合彩色图象。基本部分，不可缺省。
Band: 选用的波段。基本部分，不可缺省。
Alpha: 方向角。基本部分，不可缺省。
Row: 定位点行号。基本部分，不可缺省。
Col: 定位点列号。基本部分，不可缺省。
Xr: 定位点的 X坐标。基本部分，不可缺省。
Yc: 定位点的 Y坐标。基本部分，不可缺省。
Dr: 象素在行方向上的地面分辨率。基本部分，不可缺省。
Dc: 象素在列方向上的地面分辨率。基本部分，不可缺省。
Coordinate: 坐标系， G表示测量坐标系、 M表示数学坐标系。基本部分，缺省为 M。
Projection: 投影类型。扩充部分。
Spheroid: 参考椭球体。扩充部分。
Parameters: 投影参数。根据不同的投影有不同的参数表 ,格式不作严格限定 ,但必须在同一行内表达完毕。扩充部分。
MinV: 象素的最小值。扩充部分。
MaxV: 象素的最大值。扩充部分。
“TIFF文件 ”和 “BMP文件 ”参照相关标准 ,本文不再定义 ,存贮的顺序是从北到南 ,从西到东。
7 格网数据交换格式
7.1 格网的值是该格网的要素类型编码或高程。
7.2 数据文件包含两部分 : 文件头和数据体。
7.3 文件头的信息分两类 :基本的且必须的信息和扩充的附加信息。扩充部分可以省略。
7.4 格网数据的存贮采取从北到南 ,从西到东的顺序，并以纯文本存贮。
7.5 内容和格式
<格网数据交换格式 > ::= <文件头 ><数据体 >
<文件头 > ::=
DataMark: CNSDTF-RAS|CNSDTF-DEM<CR>Version: <浮点 ><CR>Unit: <字符 ><CR>
Alpha: <浮点 ><CR>Compress: 0|1<CR>X0: <浮点 ><CR>Y0: <浮点 ><CR>
DX: <浮点 ><CR>DY: <浮点 ><CR>Row: <整数 ><CR>Col: <整数 ><CR>
ValueType: Char|Integer<CR>HZoom: <整数 ><CR>
[Coordinate: G|M<CR>]
[Projection: <字符串 ><CR>Spheroid: <字符串 ><CR>Parameters: <字符串 ><CR>]
[MinV: <字符 |整数 ><CR>MaxV: <字符 |整数 ><CR>]
其中 :
DataMark: 中国地球空间数据交换格式 -格网数据交换格式 (CNSDTF-RAS或 CNSDTF-DEM)的标志。基本部分，不可缺省。
Version: 该空间数据交换格式的版本号。基本部分，不可缺省。
Unit: 坐标单位。 M表示米 ,D表示经纬度。基本部分，不可缺省。
Alpha: 方向角。基本部分，不可缺省。
Compress: 压缩方法。 0表示不压缩 ,1表示游程编码。基本部分，不可缺省。
X0: 左上角原点 X坐标。基本部分，不可缺省。
Y0: 左上角原点 Y坐标。基本部分，不可缺省。
DX: X方向的间距。基本部分，不可缺省。
DY: Y方向的间距。基本部分，不可缺省。
Row: 行数。基本部分，不可缺省。
Col: 列数。基本部分，不可缺省。
ValueType: 格网值的类型。基本部分，不可缺省。
HZoom: 高程放大倍率。基本部分，不可缺省。
设置高程的放大倍率 ,使高程数据可以整数存贮 ,如高程精度精确到厘米 ,高程的放大倍率为 100。如果不是 DEM则 HZoom为 1。
Coordinate: 坐标系， G表示测量坐标系、 M表示数学坐标系。基本部分，缺省为 M。
Projection: 投影类型。扩充部分。
Spheroid: 参考椭球体。扩充部分。
Parameters: 投影参数。根据不同的投影有不同的参数表 ,格式不作严格限定 ,但必须在同一行内表达完毕。扩充部分。
MinV: 格网最小值。扩充部分。
MaxV: 格网最大值。扩充部分。
这里指乘了放大倍率以后的最大最小值。
<数据体 > ::= {<格网值 >{,<格网值 >} <CR>} | {<格网值 ><整数 >{,<格网值 ><整数 >} <CR>}
压缩方法为 0时采用数据体的前一种格式 ;压缩方法为 1时采用数据体的后一种格式 ,<整数 >表示游程长度。数据体中的总数值单元数由行数乘列数决定 ,在文件中每 10个单元记录一行。
<格网值 > ::= <字符串 >|<整数 >
附录 A
（标准的附录）
空间数据的概念和对象模型
A． 1 概念模型
本标准所规定的空间数据交换格式概念模型包括三个部分 :空间现象模型、用于表示空间现象的空间对象模型和解释空间对象与空间现象相互联系的空间要素模型。
下列术语定义了概念模型的各个部分 :
(a) 现象 (Phenomenon)�D�D事实、存在或环境。如 :中山路、京九铁路、顺义县等都是现象；
(b) 分类 (Classification)�D�D把相似现象划分为同一类。一个具体的现象是所属类的一个实例。如 :中山路是路类的一个实例。
(c) 综合 (Generalization)�D�D把一些类抽象到另一些类的过程。一般的类包括所有子类的一个实例。如 :下水道包括于更一般的设施类之中。
(d)聚集 (Aggregation)�D�D由元现象构造更加复杂现象的操作。例如 :房屋是墙、门窗和房顶的聚合。
(e) 联合 (Association)�D�D采用不同于分类的标准把现象分成不同的集合。例如 :水泥路可能与水泥下水道、水泥闸门以及其他由水泥构筑起来的现象有关。
A． 1． 1 空间现象模型
CNSDTF转换关于现象的信息 ,这些现象定义于时空中 ,并且采用一个固定的位置来描述 ,这种现象也叫空间现象。所有现象都属于某一现象类。如 :红星农场属于农场类 ,该类所具有的特征称为属性 ,例如 :面积是农场的一种属性。一个属性值是该属性所在类的一个现象的具体量或质。例如 :红星农场拥有面积 1600亩。
一个给定的现象是否属于某一类 ,决定于该类的定义。这个定义由对该类的所有成员共有特征的描述所组成 ,它还包括这一类区别于其他类的特征。这些定义特征是把某些现象归入这一类或将其他一些现象从这一类排除的充分必要条件。数据采集者能够定义哪些类现象是有意义的。现象的这些类别称为实体类型。而具体的现象称为实体实样。
每一类都有自己的特定属性。每类的属性具有关键属性。关键属性值的组合形成了每个实体唯一的识别标志。
实体实样可以聚合成为一个不同类型实体的实样。
多种实体类型可以依据多个类所共有的定义特征归纳为专题。专题也可有其自己的属性 ,包括名称。
实体实样的联系是用定义实体类型之外的特征定义的。一种公共的联系是空间域 ,将具有指定范围内坐标值的所有实体实样聚合在一起。另一个有用的联系是时间域。 CNSDTF把实体实样表示为表态的 ,没有时间维。然而 ,可将时间属性值如将年代赋给实体实样 ,并用这些属性值把实样联成具有公共时间范围的集合。
关系是联系的一种特殊情况。关系存在于实体类型之间。关系实样是具有唯一关系值的实体实样之间的联系。
A． 1． 2 空间对象模型
实体实样具有一种数字表示。这种数字由一个或多个的空间对象组成。一个空间对象可以是许多其他空间对象的聚合 ,但并不需要所有这些空间对象都表示一个实体实样。能表示单个实体实样的全部内容的空间对象是一个实体对象 ,它可以归入某个实体对象类。而且实体对象具有许多通性和联系 :一个实体专题的表示就是一个对象专题 ,同样实体空间域的表示都是对象空间域。一般说来 ,实体实样和实体对象间的相互对应是与实体和对象的所有特征相对应的。
实体对象具有位置属性 (空间地址 )、非位置属性和相互关系 (拓扑关系 )。实体对象的属性和相互关系不必象它们对应的实体实样的属性与相互关系那么详细。用于区别特定实样的关键属性在实际的转换中可能不出现 ,而实体对象记录的标识符可能是区别实样的唯一途径。
空间对象不管它们是否是实体对象都可能具有独立的属性 ,所有对象都可以实体实样可能有的同样通用的方式进行分类、聚合和联系。
本标准定义一个简单的空间对象的集合。这些简单的空间对象或者是原始对象 (不能由其它对象聚合而成 ),或者是仅仅由属于不同类的空间对象聚合而成 (例如 ,多边形不能由多边形集合而成 ,而只能由弧段集合组成 )。组合对象是仅有的例外 ,组合空间对象可以由简单的对象或其它组合对象聚合而成。
A． 1． 3 空间要素模型
传统的地理数据处理过程中的术语没有把现象和其表示区别开来。二者都当作要素。为了明确起见 ,在本标准中要素被定义为现象和其表示的结合。一个要素实例由一个实体实样和表示它的实样对象组成 ,并属于某种要素 (要素 )类型。
A． 2 空间对象的定义
空间对象含有两方面的特性 :几何特性和属性特性。几何特性由下面的定义区分；属性特性由属性编码区分。空间对象有下列几种类型 :
(1) 纯几何类型。例如一个独立点、一条等高线 ,只有几何位置 ,没有对象之间的关联关系。
(2) 几何拓扑类型。既有几何位置 ,又有拓扑关系 ,如结点、公共弧段。
(3) 纯拓扑类型。仅有拓扑关联关系 ,通常用于定义空间分析操作。
(4) 空间要素。有属性特征 ,或者说有确定的要素意义 ,有对应的要素编码和属性描述记录 ,如油井、房子、公园等。
(5) 非要素类型。没有确定的要素意义 ,只是为了便于空间数据的表达和组织方便设置的中间对象 ,如一个纯粹的结点或多边形的公共弧段。
前三种由几何概念区分 ,后两种以属性概念区分。它们之间有概念的交叉 ,以上划分主要是为了下面的叙述方便。
A． 2． 1 零维空间对象
(1) 独立点状要素。是纯几何类型 ,但它是一个空间要素 ,有对应的属性编码和属性表。
(2) 纯结点。是几何拓扑元素 ,不是一种要素类型。这种结点只是用来表达与弧段的关联关系和几何位置。
(3) 结点要素。既是几何拓扑类型 ,又是空间要素。如电力线之间的结点往往是一个配电站。
(4) 注记参考点。用作注记位置的参考 ,可将它放入注记的数据结构中。
(5) 多边形标识点。是多边形的辅助信息 ,可放在多边形的数据结构中。
以上 (1)、 (2)、 (3)三类空间对象有许多相似性 ,又有交叉的概念联系 ,所以在设计数据结构时 ,把它们作为一类对象处理 ,称为结点一点状类型 ,并用特征描述码将它们区分为不同的对象。
A． 2． 2 一维对象
(1) 拓扑弧段 :它是几何拓扑类型。弧段没有分支 ,有起结点和终结点。它可能是线状要素的一部分 ,也可能仅是面状要素的边界 ,并且甚至可以既是面状要素的边界 ,同时又是一个或多个线状要素的一部分或全部。弧段本身一般没有要素意义 ,但是如果一条弧段本身就是一个线状要素 ,那么它可以直接赋以要素的编码 ,连接到属性表 ,拓扑弧段可能有折线、圆、圆弧、光滑曲线等几何特征。
(2) 无拓扑弧段 :它是一种纯几何要素 ,有些系统称为面条要素 (Spaghetti)。例如等高线 ,一般不需要考虑它的起结点、终结点、左多边形和右多边形。它比前面所述的拓扑弧段要简单得多。就形状上说 ,无拓扑弧段也有光滑与不光滑之分。
拓扑弧段与无拓扑弧段可合并成一类 ,共用一个数据结构 ,并用特征码进行区分。
(3) 线状要素 :一个线状要素可以由一条或若干条弧段组成。线状要素允许有分支和交叉 ,以使它扩展到处理河流流域和交通等问题。线状要素必须有属性编码 ,并联接到属性表。
A． 2． 3 二维对象
(1) 简单多边形 :包括一个外边界但不带内岛的多边形。
(2) 带岛的多边形 :由外边界和一个或多个内岛组成的多边形。
(3) 复合多边形 :由多个简单多边形和 /或带岛多边形组成的多边形。
(4) 广义多边形 :仅有内岛边界没有外边界的多边形。
(5) 象元 :一个二维图素 ,它是最小的不可再分的图象元素。
(6) 网络单元 :网格单元的二维对象。
A． 2． 4 集合对象
(1) 图象或称数字影像 :它是组成一个图案的 ,在空间上规则排列的元素的二维矩阵。
(2) 格网 :它是某种面的规则或接近规则的镶拼。通常是长方形或正方形。如基于格网的 GIS,或数字高程模型。
(3) 层 :由一个或多个要素类组成。它可以是矢量数据集合 ,也可能是影像或格网。
附录Ｂ
（提示的附录）
矢量数据交换格式样本
HeadBegin
DataMark: CNSDTF-VCT
VerSion: 1.0
Unit: M
Dim: 2
Topo: 0
MinX: -30.070
MinY: 0.000
MaxX: 565.530
MaxY: 500.000
ScaleM: 500
Projection: Unkown
Spheroid: Unkown
Parameters: Unkown
Date: 1999
Separator: ,
HeadEnd
FeatureCodeBegin
6520,等高线 ,Line,0,TCONTOUR
6530,高程点 ,Point,0,TELEV
House,房屋 ,Polygon,0,THOUSE
Road,公路 ,Line,0,TROAD
Lakes,湖 ,Polygon,0,TLAKE
FeatureCodeEnd
TableStructureBegin
TCONTOUR,1
elevation,Float
TELEV,1
elevation,Float
THOUSE,2
层数 ,Integer
户主 ,Char,8
TROAD,1
等级 ,Char,4
TLAKE,3
name,Char,12
perimeter,Char,8
area,Char,8
TableStructureEnd
PointBegin
6
6530
Elev
1
48.750000,270.000000
PointEnd
LineBegin
5
6520
Contour
1
35
172.500000,262.500000
175.000000,281.250000
180.000000,323.750000
188.750000,365.000000
215.000000,413.750000
235.000000,442.500000
265.000000,463.750000
327.500000,480.000000
385.000000,482.500000
422.500000,477.500000
436.250000,467.500000
455.000000,437.500000
465.000000,415.000000
465.000000,393.750000
465.000000,370.000000
463.750000,346.250000
456.250000,321.250000
438.750000,281.250000
428.750000,245.000000
416.250000,205.000000
408.750000,178.750000
398.750000,150.000000
382.500000,120.000000
360.000000,98.750000
332.500000,87.500000
320.000000,85.000000
293.750000,85.000000
255.000000,85.000000
221.250000,93.750000
180.000000,111.250000
175.000000,140.000000
166.250000,168.750000
158.750000,193.750000
158.750000,218.750000
172.500000,262.500000
4
6520
Contour
1
23
216.250000,252.500000
216.250000,268.750000
223.750000,296.250000
233.750000,316.250000
255.000000,330.000000
278.750000,333.750000
291.250000,335.000000
301.250000,328.750000
303.750000,322.500000
313.750000,306.250000
318.750000,287.500000
318.750000,270.000000
317.500000,253.750000
307.500000,241.250000
295.000000,230.000000
272.500000,223.750000
250.000000,208.750000
237.500000,208.750000
228.750000,210.000000
226.250000,215.000000
215.000000,227.500000
213.750000,237.500000
216.250000,252.500000
2
6520
Contour
1
14
102.500000,423.750000
113.750000,412.500000
116.250000,395.000000
121.250000,383.750000
122.500000,371.250000
128.750000,352.500000
133.750000,322.500000
133.750000,293.750000
133.750000,268.750000
127.500000,237.500000
117.500000,201.250000
103.750000,175.000000
81.250000,147.500000
66.250000,137.500000
6520
Contour
1
22
20.000000,282.500000
20.000000,300.000000
31.250000,317.500000
41.250000,327.500000
51.250000,333.750000
68.750000,335.000000
76.250000,332.500000
88.750000,321.250000
91.250000,307.500000
92.500000,287.500000
92.500000,272.500000
88.750000,255.000000
83.750000,247.500000
70.000000,235.000000
53.750000,222.500000
40.000000,222.500000
26.250000,225.000000
21.250000,232.500000
15.000000,245.000000
13.750000,256.250000
17.500000,273.750000
20.000000,282.500000
14
Road
Road
1
7
-30.070000,350.110000
64.970000,348.840000
213.240000,347.570000
296.880000,362.780000
423.600000,393.190000
473.020000,418.540000
565.530000,486.970000
LineEnd
PolygonBegin
19
House
House
321.470000,173.980000
5
295.920000,173.010000
345.460000,201.160000
367.490000,161.900000
317.240000,133.710000
295.920000,173.010000
5
318.950000,162.160000
342.200000,175.120000
350.160000,161.010000
326.430000,147.640000
318.950000,162.160000
0
7
Lakes
Lakes
266.250000,268.750000
23
216.250000,252.500000
216.250000,268.750000
223.750000,296.250000
233.750000,316.250000
255.000000,330.000000
278.750000,333.750000
291.250000,335.000000
301.250000,328.750000
303.750000,322.500000
313.750000,306.250000
318.750000,287.500000
318.750000,270.000000
317.500000,253.750000
307.500000,241.250000
295.000000,230.000000
272.500000,223.750000
250.000000,208.750000
237.500000,208.750000
228.750000,210.000000
226.250000,215.000000
215.000000,227.500000
213.750000,237.500000
216.250000,252.500000
0
PolygonEnd
AnnotationBegin
12
6520
Contour
宋体
0
400,0,F
5.000000,5.000000
0.000000
17.8
1
48.750000,270.000000,0.000000
15
Road
Road
宋体
0
400,0,F
10.000000,10.000000
0.000000
公路
2
73.840000,352.640000,0.000000
336.160000,375.450000,0.244979
13
Lakes
Lakes
宋体
0
400,0,F
10.000000,10.000000
0.000000
小湖
1
254.110000,273.470000,0.000000
AnnotationEnd
AttributeBegin
TELEV
6,17.8
TableEnd
TCONTOUR
5,5
4,3.72
2,10
1,15
TableEnd
TROAD
14,二级
TableEnd
THOUSE
19,3,王国良
TableEnd
TLAKE
7,小湖 ,372.088955,10012.5
TableEnd
AttributeEnd
附录Ｃ
（提示的附录）
影像附加信息交换格式样本
DataMark:CNSDTF-IMG
Version:1.0
Unit:D
Type:TIFF
SaveWay:B
Band:RGB
Alpha:0.0
Row:
Col:
Xr
:
Yc:
Dr:0.9
Dc:0.9
MinV:0
MaxV:210
附录Ｄ
（提示的附录）
格网数据交换格式样本
DataMark:NSDTF-DEM
Version:1.0
Unit:M
Alpha:0.0
Compress:0.0
X0:458312.500
Y0:3458762.500
DX:12.500
DY:12.500
Row:366
Col:473
ValueType:Integer
Hzoom:100
MinV:
MaxV:
-99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999
-99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999
-99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999
-99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999
-99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999
-99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999 -99999
-99999 -99999 -99999 -99999 -99999 -99999 1891 1904 1917 1930
1943 1955 1968 1981 1994 1837 1854 2004 2029 2049
2071 2102 2130 2157 2183 2203 2220 2242 2269 2299
2331 2362 2394 2425 2456 2488 2537 2597 2657 2717
2783 2855 2915 2982 2999 3018 3029 3036 3041 3069
3098 3126 3154 3183 3211 3240 3268 3298 3328 3358
3388 3419 3449 3480 3571 3730 3888 4013 4058 4103
4151 4202 4253 4304 4355 4406 4457 4513 4598 4680
4737 4787 4821 4852 4887 4924 4963 5006 5111 5228
5345 5457 5587 5725 5830 5909 5943 5926 5924 5990
6128 6303 6479 6808 7194 7555 7930 8362 8900 9359
9988 10515 11244 11703 11960 12076 12045 11997 11954 11881
11712 11448 11078 10525 9946 9757 9442 9163 8853 8504|
…………………………………………………………………………………………………………
…………………………………………………………………………………………………………
…………………………………………………………