perlreftut--->1

One of the most important new features in Perl 5 was the capability to manage complicated data structures like multidimensional arrays and nested hashes. To enable these, Perl 5 introduced a feature called 'references', and using references is the key to managing complicated, structured data in Perl. Unfortunately, there's a lot of funny syntax to learn, and the main manual page can be hard to follow. The manual is quite complete, and sometimes people find that a problem, because it can be hard to tell what is important and what isn't.
对于perl5来说，最重要的新特性之一就是能够处理复杂的数据结构，比如：多维数组和嵌套哈希。为了能处理这些复杂的数据结构，perl5引入了一个称之为“引用”的新特性。并且在perl中使用“引用"是管理复杂结构化数据的关键。不幸的是，需要学习一些有趣的语法，而且主手册页不利于理解。虽然说perl的手册是非常的完整，但是有时人们发现一个问题，因为他们不能判断什么内容重要，什么内容不重要。

Fortunately, you only need to know 10% of what's in the main page to get 90% of the benefit. This page will show you that 10%.

幸运的是，你只需要了解手册10%的内容就能获得90%的收益，该文档将会显示你所需要的10%的内容。

Who Needs Complicated Data Structures?
One problem that came up all the time in Perl 4 was how to represent a hash whose values were lists. Perl 4 had hashes, of course, but the values had to be scalars; they couldn't be lists.
一直伴随着perl4的一个问题是：怎样显示一个值为列表的hash。perl4中存在hash数据结构，但是hash中的key对应的value必须是scalar（平面变量），而不能是列表。

Why would you want a hash of lists? Let's take a simple example: You have a file of city and country names, like this:

        Chicago, USA
        Frankfurt, Germany
        Berlin, Germany
        Washington, USA
        Helsinki, Finland
        New York, USA

and you want to produce an output like this, with each country mentioned once, and then an alphabetical list of the cities in that country:

        Finland: Helsinki.
        Germany: Berlin, Frankfurt.
        USA:  Chicago, New York, Washington.

The natural way to do this is to have a hash whose keys are country names. Associated with each country name key is a list of the cities in that country. Each time you read a line of input, split it into a country and a city, look up the list of cities already known to be in that country, and append the new city to the list. When you're done reading the input, iterate over the hash as usual, sorting each list of cities before you print it out.
对于上述问题通常的做法是，建立一个hash然后将country名字作为hash的key，将属于该country的城市作为该key的value(s)，但是key对应的value是一个list（列表）。每次读入一行内容的时候，判断country是否存在，如果存在就将city追加到对应的list中，如果country没有在hash中那么就针对该country创建一个空list，然后将对应的value(s)追加到该list当中来，当要输出内容的时候，可以先sort一下，在输出，或者不sort就输出。
If hash values can't be lists, you lose. In Perl 4, hash values can't be lists; they can only be strings. You lose. You'd probably have to combine all the cities into a single string somehow, and then when time came to write the output, you'd have to break the string into a list, sort the list, and turn it back into a string. This is messy and error-prone. And it's frustrating, because Perl already has perfectly good lists that would solve the problem if only you could use them.
但是在perl4中hash对应的value不能是一个list必须是一个scalar。所以你不能像上面那样解决问题。你不得不使用其他的方法将country对应的cities合并到一个单一的字符串中，然后当输出的时候，你必须将单一的字符串分割并sort然后在将sort后的字符合并到一个单一的串中，这样处理问题的时候会比较的繁琐而且很容易出错。

The Solution

By the time Perl 5 rolled around, we were already stuck with this design: Hash values must be scalars. The solution to this is references.
在perl5之前我们不得不接受perl中的hash的value是一个scalar的事实，但是到了perl5的时代，一切变的简单了，因为reference到来了。

A reference is a scalar value that refers to an entire array or an entire hash (or to just about anything else). Names are one kind of reference that you're already familiar with. Think of the President of the United States: a messy, inconvenient bag of blood and bones. But to talk about him, or to represent him in a computer program, all you need is the easy, convenient scalar string "Barack Obama".
引用是一个指向整个数组或者整个hash（或者任何其他的数据结构）的标量值。

References in Perl are like names for arrays and hashes. They're Perl's private, internal names, so you can be sure they're unambiguous. Unlike "Barack Obama", a reference only refers to one thing, and you always know what it refers to. If you have a reference to an array, you can recover the entire array from it. If you have a reference to a hash, you can recover the entire hash. But the reference is still an easy, compact scalar value.
perl的引用就像数组和哈希一样。他们是perl私有的内部的名字，因此你能够将他们唯一化。
You can't have a hash whose values are arrays; hash values can only be scalars. We're stuck with that. But a single reference can refer to an entire array, and references are scalars, so you can have a hash of references to arrays, and it'll act a lot like a hash of arrays, and it'll be just as useful as a hash of arrays.

We'll come back to this city-country problem later, after we've seen some syntax for managing references.

Syntax

There are just two ways to make a reference, and just two ways to use it once you have it.
创建引用的两种方法
Making References

Make Rule 1
方法一：在标量、数组、哈希前加一个"\"。（应用在命名的数组和hash中代码块中）

If you put a \ in front of a variable, you get a reference to that variable.

    $aref = \@array;         # $aref now holds a reference to @array
    $href = \%hash;          # $href now holds a reference to %hash
    $sref = \$scalar;        # $sref now holds a reference to $scalar

Once the reference is stored in a variable like $aref or $href, you can copy it or store it just the same as any other scalar value:

    $xy = $aref;             # $xy now holds a reference to @array
    $p[3] = $href;           # $p[3] now holds a reference to %hash
    $z = $p[3];              # $z now holds a reference to %hash

These examples show how to make references to variables with names. Sometimes you want to make an array or a hash that doesn't have a name. This is analogous to the way you like to be able to use the string "\n" or the number 80 without having to store it in a named variable first.

Make Rule 2
方法二：针对于匿名数组和hash

[ ITEMS ] makes a new, anonymous array, and returns a reference to that array. { ITEMS } makes a new, anonymous hash, and returns a reference to that hash.
"[ ITEMS ]"创建了一个新的匿名的数组并且返回了该数组的引用，"{ ITEMS }"创建了一个匿名的hash并返回了该哈希的引用。

    $aref = [ 1, "foo", undef, 13 ];
    # $aref now holds a reference to an array

    $href = { APR => 4, AUG => 8 };
    # $href now holds a reference to a hash

The references you get from rule 2 are the same kind of references that you get from rule 1:

        # This:
        $aref = [ 1, 2, 3 ];

        # Does the same as this:
        @array = (1, 2, 3);
        $aref = \@array;

The first line is an abbreviation for the following two lines, except that it doesn't create the superfluous array variable @array.

If you write just [], you get a new, empty anonymous array. If you write just {}, you get a new, empty anonymous hash.
Using References

What can you do with a reference once you have it? It's a scalar value, and we've seen that you can store it as a scalar and get it back again just like any scalar. There are just two more ways to use it:
处理引用（去引用中的值）
Use Rule 1----方法一：

You can always use an array reference, in curly braces, in place of the name of an array. For example, @{$aref} instead of @array.

Here are some examples of that:
对于一个数组引用取值的时候需要在该引用前加一个"@"hash的时候需要添加一个"%"标量的时候需要添加一个"$".

Arrays:

        @a              @{$aref}                An array
        reverse @a      reverse @{$aref}        Reverse the array
        $a[3]           ${$aref}[3]             An element of the array
        $a[3] = 17;     ${$aref}[3] = 17        Assigning an element

On each line are two expressions that do the same thing. The left-hand versions operate on the array @a. The right-hand versions operate on the array that is referred to by $aref. Once they find the array they're operating on, both versions do the same things to the arrays.

Using a hash reference is exactly the same:

        %h              %{$href}              A hash
        keys %h         keys %{$href}         Get the keys from the hash
        $h{'red'}       ${$href}{'red'}       An element of the hash
        $h{'red'} = 17  ${$href}{'red'} = 17  Assigning an element

Whatever you want to do with a reference, Use Rule 1 tells you how to do it. You just write the Perl code that you would have written for doing the same thing to a regular array or hash, and then replace the array or hash name with {$reference}. "How do I loop over an array when all I have is a reference?" Well, to loop over an array, you would write
遍历一个数组
        for my $element (@array) {
           ...
        }
遍历一个数组引用
so replace the array name, @array, with the reference:

        for my $element (@{$aref}) {
           ...
        }
遍历一个hash
"How do I print out the contents of a hash when all I have is a reference?" First write the code for printing out a hash:

        for my $key (keys %hash) {
          print "$key => $hash{$key}\n";
        }
遍历一个hash引用
And then replace the hash name with the reference:

        for my $key (keys %{$href}) {
          print "$key => ${$href}{$key}\n";
        }