Android 12 快速适配

Android 12 需要更新适配点并不多，本篇主要介绍最常见的两个需要适配的点：android:exported 和 SplashScreen 。

一、android:exported

它主要是设置 Activity 是否可由其他应用的组件启动， “true” 则表示可以，而“false”表示不可以。

若为“false”，则 Activity 只能由同一应用的组件或使用同一用户 ID 的不同应用启动。

当然不止是 Activity， Service 和 Receiver 也会有 exported 的场景。
一般情况下如果使用了 intent-filter，则不能将 exported 设置为“false”，不然在 Activity 被调用时系统会抛出 ActivityNotFoundException 异常。

相反如果没有 intent-filter，那就不应该把 Activity 的 exported 设置为true ，这可能会在安全扫描时被定义为安全漏洞。

而在 Android 12 的平台上，也就是使用 targetSdkVersion 31 时，那么你就需要注意：

如果 Activity 、 Service 或 Receiver 使用 intent-filter ，并且未显式声明 android:exported 的值，App 将会无法安装。

这时候你可能会选择去 AndroidManifest 一个一个手动修改，但是如果你使用的 SDK 或者第三方库没有支持怎么办？或者你想要打出不同 target 平台的包？这时候下面这段 gradle 脚本可以给你省心：

com.android.tools.build:gradle:3.4.3 以下版本

/**
 * 修改 Android 12 因为 exported 的构建问题
 */
android.applicationVariants.all { variant ->
    variant.outputs.all { output ->
        output.processResources.doFirst { pm ->
            String manifestPath = output.processResources.manifestFile
            def manifestFile = new File(manifestPath)
            def xml = new XmlParser(false, true).parse(manifestFile)
            def exportedTag = "android:exported"
            ///指定 space
            def androidSpace = new groovy.xml.Namespace('http://schemas.android.com/apk/res/android', 'android')

            def nodes = xml.application[0].'*'.findAll {
                //挑选要修改的节点，没有指定的 exported 的才需要增加
                (it.name() == 'activity' || it.name() == 'receiver' || it.name() == 'service') && it.attribute(androidSpace.exported) == null

            }
            ///添加 exported，默认 false
            nodes.each {
                def isMain = false
                it.each {
                    if (it.name() == "intent-filter") {
                        it.each {
                            if (it.name() == "action") {
                                if (it.attributes().get(androidSpace.name) == "android.intent.action.MAIN") {
                                    isMain = true
                                    println("......................MAIN FOUND......................")
                                }
                            }
                        }
                    }
                }
                it.attributes().put(exportedTag, "${isMain}")
            }

            PrintWriter pw = new PrintWriter(manifestFile)
            pw.write(groovy.xml.XmlUtil.serialize(xml))
            pw.close()
        }
    }

}

com.android.tools.build:gradle:4.1.0 以上版本

/**
 * 修改 Android 12 因为 exported 的构建问题
 */

android.applicationVariants.all { variant ->
    variant.outputs.each { output ->
        def processManifest = output.getProcessManifestProvider().get()
        processManifest.doLast { task ->
            def outputDir = task.multiApkManifestOutputDirectory
            File outputDirectory
            if (outputDir instanceof File) {
                outputDirectory = outputDir
            } else {
                outputDirectory = outputDir.get().asFile
            }
            File manifestOutFile = file("$outputDirectory/AndroidManifest.xml")
            println("----------- ${manifestOutFile} ----------- ")

            if (manifestOutFile.exists() && manifestOutFile.canRead() && manifestOutFile.canWrite()) {
                def manifestFile = manifestOutFile
                ///这里第二个参数是 false ，所以 namespace 是展开的，所以下面不能用 androidSpace，而是用 nameTag
                def xml = new XmlParser(false, false).parse(manifestFile)
                def exportedTag = "android:exported"
                def nameTag = "android:name"
                ///指定 space
                //def androidSpace = new groovy.xml.Namespace('http://schemas.android.com/apk/res/android', 'android')

                def nodes = xml.application[0].'*'.findAll {
                    //挑选要修改的节点，没有指定的 exported 的才需要增加
                    //如果 exportedTag 拿不到可以尝试 it.attribute(androidSpace.exported)
                    (it.name() == 'activity' || it.name() == 'receiver' || it.name() == 'service') && it.attribute(exportedTag) == null

                }
                ///添加 exported，默认 false
                nodes.each {
                    def isMain = false
                    it.each {
                        if (it.name() == "intent-filter") {
                            it.each {
                                if (it.name() == "action") {
                                    //如果 nameTag 拿不到可以尝试 it.attribute(androidSpace.name)
                                    if (it.attributes().get(nameTag) == "android.intent.action.MAIN") {
                                        isMain = true
                                        println("......................MAIN FOUND......................")
                                    }
                                }
                            }
                        }
                    }
                    it.attributes().put(exportedTag, "${isMain}")
                }

                PrintWriter pw = new PrintWriter(manifestFile)
                pw.write(groovy.xml.XmlUtil.serialize(xml))
                pw.close()

            }

        }
    }
}

这段脚本你可以直接放到 app/build.gradle 下执行，也可以单独放到一个 gradle 文件之后 apply 引入，它的作用就是：

在打包过程中检索所有没有设置 exported 的组件，给他们动态配置上 exported。这里有个特殊需要注意的是，因为启动 Activity 默认就是需要被 Launcher 打开的，所以 "android.intent.action.MAIN" 需要 exported 设置为 true 。（PS：应该是用 LAUNCHER 类别，这里故意用 MAIN）

如果有需要，还可以自己增加判断设置了 "intent-filter" 的才配置 exported 。

二、SplashScreen

Android 12 新增加了 SplashScreen 的 API，它包括启动时的进入应用的动作、显示应用的图标画面，以及展示应用本身的过渡效果。
它大概由如下 4 个部分组成，这里需要注意：

1 最好是矢量的可绘制对象，当然它可以是静态或动画形式。
2 是可选的，也就是图标的背景。
与自适应图标一样，前景的三分之一被遮盖 (3)。
4 就是窗口背景。
启动画面动画机制由进入动画和退出动画组成。

进入动画由系统视图到启动画面组成，这由系统控制且不可自定义。
退出动画由隐藏启动画面的动画运行组成。如果要对其进行自定义，可以通过 SplashScreenView 自定义。

b.jpg

更详细的介绍这里就不展开了，有兴趣的可以自己看官方的资料：https://developer.android.com/guide/topics/ui/splash-screen，这里主要介绍下如何适配和使用的问题。

首先不管你的 TargetSDK 什么版本，当你运行到 Android 12 的手机上时，所有的 App 都会增加 SplashScreen 的功能。

如果你什么都不做，那 App 的 Launcher 图标会变成 SplashScreen 界面的那个图标，而对应的原主题下 windowBackground 属性指定的颜色，就会成为 SplashScreen 界面的背景颜色。这个启动效果在所有应用的冷启动和热启动期间会出现。

其实不适配好像也没啥问题。

关于如何迁移和使用 SplashScreen 可以查阅官方详细文档：https://developer.android.com/guide/topics/ui/splash-screen/migrate

另外还可以参考 《Jetpack新成员SplashScreen：打造全新的App启动画面》^[8] 这篇文章，文章详细介绍了如果使用官方的 Jetpack 库来让这个效果适配到更低的 Target 平台。

而正常情况下我们可以做的就是：

• 1、升级 compileSdkVersion 31 、 targetSdkVersion 31 & buildToolsVersion '31.0.0'
• 2、 添加依赖 implementation "androidx.core:core-splashscreen:1.0.0-alpha02"
• 3、增加 values-v31 的目录
• 4、添加 styles.xml 对应的主题，例如：

5、给你的启动 Activity 添加这个主题，不同目录下使用不同主题来达到适配效果。