VBS上传文件

阅读更多

ON ERROR RESUME NEXT
Set FSO=CreateObject("Scripting.FileSystemObject")
'============================================================================
'以下为配置区
'============================================================================
strComputer="ftp" 'FTP主机名或主机IP(如:"192.168.1.1")
strUserName="UserName" 'FTP用户名(如:"test")
strPassword="PASSWORD" 'FTP用户密码(如:"123456")
strFtpDir="Record" 'FTP目录(如:"Dir/subDir")
strUpFileList="D:\a.txt,D:\b.txt" '待上传文件的路径列表
strTip="上传完成!" '上传完成后的提示
IsTip=True '是否显示提示(值为True或False)
nTime=0 '提示显示时间（0为一直显示直到用户确认）
'============================================================================
'以下无需修改
'============================================================================
test=UpLoad(strComputer,strFtpDir,strUserName,strPassword,strUpFileList,IsTip,strTip,nTime)
'============================================================================
Function UpLoad(strComputer,strFtpDir,strUserName,strPassword,strUpFileList,IsTip,strTip,nTime)
ON ERROR RESUME NEXT
Set FSO=CreateObject("Scripting.FileSystemObject")
Set WshShell=CreateObject("Wscript.Shell")
strFile=FSO.GetDriveName(FSO.GetSpecialFolder(0))&"\upload"
Do While FSO.FileExists(strFile&".tmp")
i=i+1
strFile=strFile&Cstr(i)
Loop
strFile=strFile&".tmp"
set f=FSO.OpenTextFile(strFile,2,True)
f.WriteLine "open "&strComputer
f.WriteLine strUserName
f.WriteLine strPassword
strFtpDirs=Split(strFtpDir,"/")
For Each strFtpDir In strFtpDirs
f.WriteLine "mkdir "&strFtpDir
f.WriteLine "cd "&strFtpDir
Next
strUpFiles=Split(strUpFileList,",")
For Each strUpFile In strUpFiles
f.WriteLine "put "&strUpFile
Next
f.WriteLine "bye"
f.Close
WshShell.Run "ftp -s:"&strFile,vbHide,True
FSO.DeleteFile strFile
If IsTip Then WshShell.Popup strTip,nTime,"由【网络e蜜蜂】制作",vbInformation
UpLoad=True
End Function
'============================================================================

 

通过FTP上传文件的VBS脚本

 

★§欢乐共享§★

 

<功能>
将若干文件上传到FTP服务器上。

 

<注意>
“strPassword=”这项可以会泄露你的登陆密码，建议将VBS编译后使用
VBS编译器下载地址：http://cmdos.net/soft/sort017/down-637.html

 

<使用说明>
strComputer=设为你的FTP服务器名或IP
strUserName=登陆FTP的用户名
strPassword=登陆FTP对应的密码
strFtpDir=登陆FTP根目录后的相对目录（为空则为FTP根目录）
strUpFileList=待上传文件的路径列表
strTip=上传完成后的提示
IsTip= 是否显示提示
nTime= 提示显示时间（0为一直显示直到用户确认）

 

<建议>
建议用EditPlus打开，语法鲜明，你可以很好的看懂！