Scilab的基本二维绘图函数

plot
完整格式为:plot(x1,y1,,x2,y2,,.....,xN,yN,)
通过LineSpec1可以为每个点设置其线型，颜色，标记形式。线型有（-,--,:,-.,），颜色有（r,g,b,c,m,y,k,w，如果没有指定颜色，scilab内部会有一个颜色列表为不同的曲线绘制不同的颜色），标记类型（+，o,*,.,x,'square','diamon',^,v,>,<,'pentagram','none'）。plot函数与matlab的plot函数兼容。

plot2d
plot2d函数提供了功能强大的二维曲线绘制方法，并可以对线型，坐标轴，标记等进行控制
完整格式为：plot2d([x],y,)
x和y均可以为实矩阵或向量；中的style用于控制绘制线型，大于零为连接的曲线，而小于零则采用标记给出各个点的位置，线型取值为1~6，而小于零时取值为0~-14，通过这些线型的选择，可以绘制出各种各样的曲线形式；logflag用于确定坐标轴的尺度为线性或对数形式，可以取值'n'或'l'；rect用于设置包含曲线的最小矩形，该参数可以与frameflag配合用于指定坐标轴边界；frameflag用于从最小所需值计算真是的坐标范围，可以取值0~9。axesflag用于指定坐标的绘制方法，可以取值0~5。nax用于指定坐标的标注，格式为[nx,NX,ny,NY]，NX和NY给出X和Y轴的主标注数量，而nx和ny给出X和Y轴的次标注数量；leg用于设置曲线的标题，但是该方法不灵活，采用captions或legend函数比较方便。
实例：

-->x=[0:0.1:2*%pi]';
-->plot2d(x,[sin(x) sin(2*x) sin(3*x)])//绘制三条曲线，颜色分别为1,2,3

-->clf();
-->plot2d(x,[sin(x) sin(2*x) sin(3*x)],rect=[0,0,6,0.5]); //通过rect设置坐标范围

-->plot2d(x,[sin(x) sin(2*x) sin(3*x)],[1 2 3],leg="L1@L2@L3",nax=[2,10,2,10],rect=[0,-2,2*%pi,2]);//设置三条曲线的颜色为1,2,3，leg用于进行曲线标注，nax设置X轴和Y轴的标注数量，图中X和Y轴的主标注和次标注都分别为10和2个。rect=[0,-2,2*%pi,2]，设置了坐标轴的范围 clf();
-->plot2d(x,sin(x),1,frameflag=4);//frameflag设置绘图视窗为正方形，大小由x和sin（x）中最大的范围所确定，这边为7。

clf();
-->plot2d(x,sin(x),1,frameflag=6);//从数据x和sin(x)自动计算最适合的绘图视窗范围，

-->clf();
-->plot2d(x,sin(x),-1);//只会出坐标处的标记，不进行曲线绘制
-->plot2d(x,2*sin(x),12);
-->plot2d(2*x,cos(x),3);//之前绘制的曲线会自动重绘以适应当前的坐标轴

-->clf();
-->plot2d(x,sin(x),leg="sin(x)");//绘图，设置其图形注释为sin(x)
-->a=gca();//得到当前坐标轴句柄
-->a.y_location="right";//设置其y轴在图形右边

-->clf();
-->plot2d(x-4,sin(x),1,leg="sin(x)");//绘图
-->a=gca();
-->a.x_location="origin";
-->a.y_location="origin";//设置x和y坐标轴均位于原点

对有plot2d建立的实体进行操作

-->clf();
-->plot2d(x,[sin(x) sin(2*x) sin(3*x)],[1 2 3],leg=L1@L2@L3);//绘出三条曲线

-->a=gca();
-->a.isoview='on';

-->a.children//列出实体的孩子，
ans  =
2 by 1 matrix of handles:
=========================
Compound //由曲线组合成的Compound
Legend   //图形标注

--> poly1=a.children(1).children(1);//得到第一条曲线
-->poly1.foreground=1;//设置其前景色
-->poly1.thickness=4;//设置其线型粗细

-->leg=a.children(2);//获得图形注释字符串
-->leg.font_style=9;//设置字型
-->leg.line_mode="on";//图形注释外部添加边框
-->a.isoview="off";//关闭isoview查看方式

plot2d2
plot2d3
plot2d4
plot2dxx（xx=1~4）形式的二维曲线绘制函数可以通过plot2d2函数选择相应的polyline_style得到相应的效果，因此plot2dxx只是plot2d具有相应线型设置的实现而已。plot2d1已经被淘汰，没有使用

-->clf();
-->x=[0:0.1:2*%pi]';
-->plot2d2(x,[sin(x) sin(2*x) sin(3*x)]);//台阶形式

-->plot2d3(x,[sin(x) sin(2*x) sin(3*x)]);//竖线形式

-->plot2d4(x,[sin(x) sin(2*x) sin(3*x)]);//箭头形式

fplot2d
fplot2d绘制由函数定义的曲线，具体格式为:fplot2d(xr,f,)，xr为向量，f为y=f(x)形式的外部定义函数。f的值由函数feval(xr,f)计算得到。
-->deff("[y]=f(x)","y=sin(x)+cos(x)")//自定义函数
-->x=[0:0.1:10]*%pi/10;
-->fplot2d(x,f);

-->clf();
-->fplot2d(1:10,'parab');//内置函数