multimport:一次性导入并合并多个文件

在用 Stata 对同一变量不同年份的数据进行整理的过程中，通常需要将某一文件夹下的若干个 excel 文件或者文本文件（txt 或 csv 格式）通过构造循环的形式读入内存中，再进行纵向追加，最终形成完整的 .dta文件。这一过程包括两个阶段：读入与纵向追加-用fs命令解决读入的问题，用openall或者采用append循环对读入的文件进行纵向追加，总的来说比较繁琐，今天介绍“一次性导入并合并多个文件”的命令：multimport。

1. 命令的安装

该命令的安装较为简单，在 Stata 命令窗口输入如下代码即可：

ssc install multimport

这样就完成了安装的过程，下面是对该命令的介绍。

2. 命令的含义

该命令的语法如下：

multimport import_method,[directory(filespec) extension(ext1[ext2...]) include(file1[file2...]) exclude(file1[file2...]) importoptions(import_method_opts) appendoptions(append_opts) ]

各个主要选项的含义：

• import_method,必选项，包括 excel 与 delimited两种方法，multimport excel表示导入 excel 文件，multimport delimited表示导入文本文件（txt 或 csv）
• directory,简记为dir,可选项，导入文件所在的路径，默认为当前工作路径
• extension,简记为ext,可选项，用以覆盖multimport默认导入的文件的扩展形式，例如，下面的代码将会导入扩展名为 txt 与 csv 的文本文件

multimport delimited,ext(csv txt)

• include 与 exclude选项，顾名思义，就是包括与排除某些文件，这些文件不会被读入内存。

multimport excel, include("svy2011.xls" "svy2012.xls" "svy2013.xls")

上述代码将导入 svy2011-svy2013 等3个 excel 文件，其余 excel 文件不会读入。

• importoptions 与 appendoptions 选项是对 import_method 与 append 方法的进一步设定，应用相对较少

3.命令的使用

下面将通过一个实例来简要说明如何通过 multimport 命令来导入并合并文本文件与 excel 文件。

3.1 文本文件的导入与合并

为方便起见，基于 Stata 官方数据集 nhanes2.dta 构造所需要的文本文件，代码如下：

• 生成文本文件

use http://www.stata-press.com/data/r14/nhanes2.dta 
tab region //region 取值为1-4
levelsof region // 根据region变量的不同取值构造暂元，并存储在r(levels)中
foreach r in `r(levels)' {
export delimited using nhanes_reg`r' if region == `r' //导出不同region分类的文本文件
}

上述代码生成了基于不同 region 的文本文件：nhanes_reg1.csv-nhanes_reg4.csv，下面将选定的文本文件导入并进行合并。

• 读入并合并文本文件

multimport delimited, clear include(nhanes_reg1.csv nhanes_reg2.csv)

上述代码将 nhanes_reg1 与 nhanes_reg2 两个 csv 文件导入并进行了纵向合并，如果想合并所有的 csv 文件，去掉 include选项即可。值得注意的是，在上述代码的执行过程中，Stata 输出界面会提示Proceed(yes/no?)，需要手动输入yes/no，较为繁琐。
为解决这一问题，加入force选项即可，强制读入并进行合并，修正后的代码如下：

multimport delimited, clear include(nhanes_reg1.csv nhanes_reg2.csv) force
save nhanes_csv,replace

3.2 excel 文件的读入与合并

excel 文件的读入与合并过程与上面的类似，同样以数据集 nhanes2.dta为例，得到相应的执行代码如下：

• 生成 excel 文件

use http://www.stata-press.com/data/r14/nhanes2.dta 
levelsof region 
foreach r in `r(levels)' {
export excel using nhanes_reg`r' if region == `r' 
}

上述代码生成了 nhanes_reg1.xls-nhanes_reg4.xls等4个 excel 文件。

• 读入并合并文件

multimport excel, clear exclude(nhanes_reg2.xls) force
save nhanes_excel,replace

上述代码剔除了名称为nhanes_reg2的 excel 文件，并将剩余的 excel 文件导入并进行合并。
以上便是multimport命令的基本内容，掌握该命令的用法后可以迅速而简洁地完成文件的读入与合并工作。