打开文件对话框缺省为缩略图方式显示

最新情况: 参见 打开公用对话框的初始视图类型问题
------------------------------------------------------

坛子上有人问到如何对使用 CommonDialog 组件显示的打开对话框缺省显示为缩略图的问题，其实上一次提出这个问题的时候我就已经回答过，可能楼主对 api 不熟悉，所以没有写出实现的代码。这次豆三版主挑出了我的马甲，只好勉为其难了。
查过 msdn 后，找到一个函数 GetOpenFileNameEx，可以指定打开对话框时的视图样式，可惜其中只描述了在  WindowsMobile 5.0/WinCE 中的导出库，Windows2k/xp/2k3 中在哪里却没有指出。试过 comdlg32 / commctrl / shell32 都没有找到，网上找了一圈也没结果，看来是专用于  WindowsMobile 5.0 的了，只好放弃。
一定要实现的话就只能模拟鼠标和键盘按键来实现了。下面就是实现这个功能的代码，由于是模拟手工操作，所以弹出菜单一定会闪现一下，虽不是很好，但也暂无好的解决方法。下面是实现此功能的简单示例，真正要用于你的程序还需要做些错误处理方面的改进：

2. #define WM_TIMER                0x0113 
3. #define TIMER_ID                100 
4. #define MOUSEEVENTF_MOVE        0x0001 
5. #define MOUSEEVENTF_RIGHTDOWN   0x0008 
6. #define MOUSEEVENTF_RIGHTUP     0x0010 
7. #define MOUSEEVENTF_ABSOLUTE    0x8000 
8. #define KEYEVENTF_KEYDOWN       0x0000 
9. #define KEYEVENTF_KEYUP         0x0002 
11. PUBLIC oForm
12. oForm = NEWOBJECT( 'MyForm' )
13. oForm.Show()
14. READ EVENTS
16. DEFINE CLASS MyForm AS form
17.   Height = 78
18.   Width = 293
19.   DoCreate = .T.
20.   AutoCenter = .T.
21.   Caption = "Form1"
22.   AllowOutput = .F.
23.   Name = "Form1"
25.   ADD OBJECT command1 AS commandbutton WITH ;
26.     Top = 24, ;
27.     Left = 180, ;
28.     Height = 27, ;
29.     Width = 84, ;
30.     Caption = "打开图片", ;
31.     Name = "command1"
33.   PROCEDURE ToggleViewStyle
34.     LPARAMETERS p1, p2, p3, p4
36.     LOCAL hWndLvw
38.     m.hWndLvw = This.FindListViewWindow()
39.     IF ( 0 != m.hWndLvw )
40.       KillTimer( This.hWnd, TIMER_ID )
41.       This.MoveMouseToListView( m.hWndLvw )
42.       mouse_event( MOUSEEVENTF_RIGHTDOWN ,0 ,0 ,0 ,0 )
43.       mouse_event( MOUSEEVENTF_RIGHTUP   ,0 ,0 ,0 ,0 )
44.       keybd_event( ASC('V') ,0 ,KEYEVENTF_KEYDOWN ,0 )
45.       keybd_event( ASC('V') ,0 ,KEYEVENTF_KEYUP   ,0 )
46.       keybd_event( ASC('H') ,0 ,KEYEVENTF_KEYDOWN ,0 )
47.       keybd_event( ASC('H') ,0 ,KEYEVENTF_KEYUP   ,0 )
48.     ENDIF
49.   ENDPROC
51.   PROCEDURE FindListViewWindow
52.     LOCAL hWndDlg, hWndLvw0, hWndLvw1
54.     m.hWndLvw1 = 0
55.     m.hWndDlg  = FindWindow( '#32770', This.dlg.DialogTitle )
56.     IF ( 0 != m.hWndDlg )
57.       m.hWndLvw0 = FindWindowEx( m.hWndDlg, 0, 'SHELLDLL_DefView', NULL )
58.       IF ( 0 != m.hWndLvw0 )
59.         m.hWndLvw1 = FindWindowEx( m.hWndLvw0, 0, 'SysListView32', NULL )
60.       ENDIF
61.     ENDIF
62.     RETURN m.hWndLvw1
63.   ENDPROC
65.   PROCEDURE api_decl
66.     DECLARE Long SetTimer IN WIN32API ;
67.       Long hWnd, Long nIDEvent, Long uElapse, Long lpTimerFunc
68.     DECLARE Long KillTimer IN WIN32API ;
69.       Long hWnd, Long uIDEvent
70.     DECLARE Long FindWindow IN WIN32API ;
71.       String lpClassName, String lpWindowName
72.     DECLARE Long FindWindowEx IN WIN32API ;
73.       Long hwndParent, Long hwndChildAfter, String lpszClass, String lpszWindow
74.     DECLARE Long mouse_event IN WIN32API ;
75.       Long dwFlags, Long dx, Long dy, Long dwData, Long dwExtraInfo
76.     DECLARE Long keybd_event IN WIN32API ;
77.       Long bVk, Long bScan, Long dwFlags, Long dwExtraInfo
78.     DECLARE Long GetCursorPos IN WIN32API ;
79.       String @ lpPoint
80.     DECLARE Long GetWindowRect IN WIN32API ;
81.       Long hWnd, String @ lpRect
82.   ENDPROC
84.   PROCEDURE MoveMouseToListView
85.     LPARAMETERS thLvw
87.     LOCAL cPoint, cRect, x0, x1, x2, y0, y1, y2
89.     m.cPoint = REPLICATE( CHR(0), 8 )
90.     m.cRect  = REPLICATE( CHR(0), 16 )
91.     GetCursorPos( @ m.cPoint )
92.     GetWindowRect( m.thLvw, @ m.cRect )
93.     m.x0 = CTOBIN( SUBSTR( m.cPoint, 1, 4 ), 'rs' )
94.     m.y0 = CTOBIN( SUBSTR( m.cPoint, 5, 4 ), 'rs' )
95.     m.x1 = CTOBIN( SUBSTR( m.cRect,  1, 4 ), 'rs' )
96.     m.y1 = CTOBIN( SUBSTR( m.cRect,  5, 4 ), 'rs' )
97.     m.x2 = CTOBIN( SUBSTR( m.cRect,  9, 4 ), 'rs' )
98.     m.y2 = CTOBIN( SUBSTR( m.cRect, 13, 4 ), 'rs' )
100.     IF !BETWEEN( m.x0, m.x1, m.x2 ) OR !BETWEEN( m.y0, m.y1, m.y2 )
101.       mouse_event( ;
102.         BITOR( MOUSEEVENTF_MOVE, MOUSEEVENTF_ABSOLUTE ), ;
103.         (m.x2-20)*0xffff/SYSMETRIC(1), (m.y2-20)*0xffff/SYSMETRIC(2), 0, 0 )
104.     ENDIF
105.   ENDPROC
107.   PROCEDURE GetPictureFile
108.     This.api_decl()
109.     BINDEVENT( This.hWnd, WM_TIMER, This, 'ToggleViewStyle' )
110.     SetTimer( This.hWnd, TIMER_ID, 50, 0 )
111.     This.dlg.FileName = ''
112.     This.dlg.ShowOpen()
113.     UNBINDEVENT( This.hWnd, WM_TIMER )
114.     RETURN This.dlg.FileName
115.   ENDPROC
117.   PROCEDURE Init
118.     This.NewObject( 'dlg', 'olecontrol',,, 'MSComDlg.CommonDialog' )
119.     This.dlg.DialogTitle = '请选择要打开的图片文件'
120.   ENDPROC
122.   PROCEDURE Unload
123.     CLEAR EVENTS
124.   ENDPROC
126.   PROCEDURE command1.Click
127.     MESSAGEBOX( Thisform.GetPictureFile() )
128.   ENDPROC
129. ENDDEFINE