android gradle 配置 build.gradle

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.4.2'
    }
}

apply plugin: 'android'

dependencies {
    compile fileTree(dir: 'libs', include: '*.jar')
}
	
android {
    compileSdkVersion 17
    buildToolsVersion "17.0.0"
	
    signingConfigs {
        myConfig {
            storeFile file("keyfile")
            storePassword "password"
            keyAlias "alias"
            keyPassword "password"
        }
    }
    
    defaultConfig {
        versionCode 1
        versionName getVersionName()
        minSdkVersion 8
        targetSdkVersion 17
    }
    
    buildTypes{
        release {
            signingConfig  signingConfigs.myConfig
            runProguard true
            proguardFile 'proguard.cfg'
        }
    }
	
    sourceSets {
        main {
            manifest {
                srcFile 'AndroidManifest.xml'
            }
            java {
                srcDir 'src'
            }
            res {
                srcDir 'res'
            }
            assets {
                srcDir 'assets'
            }
            resources {
                srcDir 'src'
            }
            aidl {
                srcDir 'src'
            }
        }
    }
}

task copyNativeLibs(type: Copy) {
    from fileTree(dir: 'libs', include: '**/*.so' )
    into 'build/native-libs'
}
tasks.withType(Compile) {
    options.encoding = "UTF-8"
}

tasks.withType(Compile) { 
    compileTask -> compileTask.dependsOn copyNativeLibs 
}
 
clean.dependsOn 'cleanCopyNativeLibs'
	 
tasks.withType(com.android.build.gradle.tasks.PackageApplication) { 
    pkgTask -> pkgTask.jniDir new File('build/native-libs')
}