windows下脚本设置安全站点及其他（bat）

@echo off
title      ie选项脚本设置
color 2f
::设置DOS窗口属性
set rr="HKCU\Console\%%SystemRoot%%_system32_cmd.exe"
reg add %rr% /v "WindowPosition" /t REG_DWORD /d 0x012e01f0 /f>nul
::WindowPosition表示窗口位置，高四位为上，低四位为左。
reg add %rr% /v "ScreenBufferSize" /t REG_DWORD /d 0x001a004d /f>nul
::ScreenBufferSize表示缓冲区尺寸，高四位为高度行，低四位为宽度列。
reg add %rr% /v "WindowSize" /t REG_DWORD /d 0x001a004d /f>nul
::WindowSize表示窗口尺寸，高四位为高度，低四位为宽度，高aH=10行，宽2dH=45列。
::也可以用mode con cols=45 lines=10来设置窗口尺寸，cols设置宽度，lines设置高度。

echo.

goto startInput

:startReInput
echo.
echo 输入的IP地址无效,请注意输入格式！
echo ##########################################################################
goto startInput

:startInput
echo.
set /p ipAddr=请输入录音网站IP地址(格式如192.168.1.100)，并按回车键:
echo %ipAddr%|findstr "^[0-9]*\.[0-9]*\.[0-9]*\.[0-9]*$">nul||goto startReInput
set _input=%ipAddr:.= %
call :check %_input%

::验证IP地址是否正确
:check
if "%4"=="" ( goto startReInput )
for %%i in (%1 %2 %3 %4) do (
if %%i gtr 255 goto startReInput
)

::以上为输入ip相关操作与ie设置无关。

:startSet
::添加信任站点
echo   ########################################################################
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Ranges\Range10" /v ":Range" /t REG_SZ /d %ipAddr% /f
reg add "HKCU\Software\Microsoft\Windows\CurrentVersion\Internet Settings\ZoneMap\Ranges\Range10" /v "http" /t REG_DWORD /d 2 /f
echo   添加信任站点  http://%ipAddr% 成功！
echo   ########################################################################

::文件下载1803/文件下载自动提示2200
::echo #####################################################
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\2" /v "2200" /t reg_dword /d 0x00000000 /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\2" /v "1803" /t reg_dword /d 0x00000000 /f
echo   文件下载设置完成！
echo   ########################################################################

::1200运行ActiveX控件和插件/1201对没有标记为安全的ActiveX控件进行初始化和脚本运行
::echo #####################################################
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\2" /v "1201" /t reg_dword /d 0x00000000 /f
reg add "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Internet Settings\Zones\2" /v "1200" /t reg_dword /d 0x00000000 /f
echo   Activex控件设置完成！
::echo #####################################################

mshta vbscript:msgbox("设置完毕,请重启浏览器 ",4096,"提示")(window.close)

exit
------------------------------------------------------------------------------------------------------------------------------------------------------

1. 首先介绍计算机定义的每个安全区域的项：Zones 。默认情况下，定义以下   5   个区域（编号从   0   到   4）：

 
0   我的电脑 
1   本地   Intranet   区域 
2   受信任的站点区域 
3   Internet   区域 
4   受限制的站点区域
注意：默认情况下，“我的电脑”不会出现在“安全”选项卡的“区域”框中。

 
其中的每项都包含以下  
 DWORD   值，用于表示自定义“安全”选项卡上的相应设置。

 
注意：除非另外声明，否则每个  
 DWORD   值等于   0、1   或   3。通常，设置为   0   则将具体操作设置为允许；设置为   1   则导致出现提示；设置为   3   则禁止执行具体操作。

 

DWORD   相关对应说明
----------------------------------------------------------------------- 
 1001           下载已签名的   ActiveX   控件 
 1004           下载未签名的   ActiveX   控件 
 1200           运行   ActiveX   控件和插件 
 1201           对没有标记为安全的   ActiveX   控件进行初始化和脚本运行 
 1206           允许   Internet   Explorer   Webbrowser   控件的脚本 
 1400           活动脚本 
 1402           Java   小程序脚本 
 1405           对标记为可安全执行脚本的   ActiveX   控件执行脚本 
 1406           通过域访问数据资源 
 1407           允许通过脚本进行粘贴操作 
 1601           提交非加密表单数据 
 1604           字体下载 
 1605           运行   Java 
 1606           持续使用用户数据 
 1607           跨域浏览子框架 
 1608           允许   META   REFRESH   * 
 1609           显示混合内容   * 
 1800           桌面项目的安装 
 1802           拖放或复制和粘贴文件 
 1803           文件下载 
 1804           在   IFRAME   中加载程序和文件 
 1805           在   Web   视图中加载程序和文件 
 1806           加载应用程序和不安全文件 
 1807                                   保留   ** 
 1808                                   保留   ** 
 1809           使用弹出窗口阻止程序   ** 
 1A00           登录 
 1A02           允许持续使用存储在计算机上的   Cookie 
 1A03           允许使用每个会话的   Cookie（未存储） 
 1A04           没有证书或只有一个证书时不提示选择客户证书   * 
 1A05           允许持续使用第三方   Cookie   * 
 1A06           允许使用第三方会话   Cookie   * 
 1A10           隐私设置   * 
 1C00           Java   权限 
 1E05           软件频道权限
 
1F00           保留   **
 
2000           二进制和脚本行为 
 2001           运行已用   Authenticode   签名的   .NET   组件 
 2004           运行未用   Authenticode   签名的   .NET   组件 
 2100           基于内容打开文件，而不是基于文件扩展名   ** 
 2101           在低特权   Web   内容区域中的网站可以导航到此区域   ** 
 2102           允许由脚本初始化的窗口，没有大小和位置限制   ** 
 2200           文件下载自动提示   ** 
 2201           ActiveX   控件自动提示   ** 
 2300           允许网页为活动内容使用受限制的协议   ** 
 
-----------------------------------------------------------------------