[039][x86汇编语言]第十五章 任务切换 内存示意图 以及 TSS相关 源码解析

学习笔记

《x86汇编语言：从实模式到保护模式》
https://www.jianshu.com/p/d481cb547e9f

运行结果

第十五章 任务切换 运行结果.png

代码使用

• nasmide.exe 编译源码文件 ：加载程序c13_mbr.asm，内核程序c15_core.asm，用户程序c15.asm；
• fixvhdwr.exe 写扇区二进制.bin文件：c13_mbr.bin（逻辑扇区号LBA：0）、c15_core.bin（LBA：1）、c15.bin（LBA：50）；
• 运行VM virtual box.

执行完两次任务切换（CALL一次，JMP一次）后的内存以及GDT状态

第15章 执行完两次任务切换后的内存示意图.png

第15章 执行完两次任务切换后的GDT示意图.png

• 如图所示，被加载到内存的，红色文字以及绿色文字代表的内容均来自于同一个用户程序c15.asm；
• 这说明，一个程序可以对应着多个运行中的副本，或者说多个任务，它们彼此之间没有任何关系，在内存中的位置不同，运行状态也不一样；
• 正因如此，即便两次切换都是切换到同一个用户程序，但本质上是切换到不同的任务，加上没有写任何内存管理的代码（比如重新释放内存），之前的任务一直留在内存里；

任务管理器

• 任务管理器，又称程序管理器：创建0特权级的内核任务，并将当前正在执行的内核代码段划归该任务，当前代码的作用是创建其他任务，管理它们，所以称做任务管理器或者叫程序管理器；

三个TSS描述符

[如图黑色和灰色部分文字]程序管理器的TSS描述符(位于内核程序c15_core.asm：标号start后面)

         ;为程序管理器的TSS分配内存空间 
         mov ecx,104                        ;为该任务的TSS分配内存
         call sys_routine_seg_sel:allocate_memory
         mov [prgman_tss+0x00],ecx          ;保存程序管理器的TSS基地址 
      
         ;在程序管理器的TSS中设置必要的项目 
         mov word [es:ecx+96],0             ;没有LDT。处理器允许没有LDT的任务。
         mov word [es:ecx+102],103          ;没有I/O位图。0特权级事实上不需要。
         mov word [es:ecx+0],0              ;反向链=0
         mov dword [es:ecx+28],0            ;登记CR3(PDBR)
         mov word [es:ecx+100],0            ;T=0
                                            ;不需要0、1、2特权级堆栈。0特级不
                                            ;会向低特权级转移控制。
         
         ;创建TSS描述符，并安装到GDT中 
         mov eax,ecx                        ;TSS的起始线性地址
         mov ebx,103                        ;段长度（界限）
         mov ecx,0x00408900                 ;TSS描述符，特权级0
         call sys_routine_seg_sel:make_seg_descriptor
         call sys_routine_seg_sel:set_up_gdt_descriptor
         mov [prgman_tss+0x04],cx           ;保存程序管理器的TSS描述符选择子 

         ;任务寄存器TR中的内容是任务存在的标志，该内容也决定了当前任务是谁。
         ;下面的指令为当前正在执行的0特权级任务“程序管理器”后补手续（TSS）。
         ltr cx 

• 程序管理器可以没有自己的LDT，可以将自己使用的段描述符安装在GDT中；
• mov word [es:ecx+0],0 ，设置TSS指针域（结合TSS的格式来看，此时ES指向0~4GB内存空间,ECX是TSS基地址）
• 程序管理器的TSS描述符必须安装在GDT中；
• 使用指令ltr，将当前任务的TSS选择子传送到处理器的TR寄存器；

ltr指令执行后，处理器用该选择子访问GDT
找到相对应的TSS描述符，将其B位置“1”
表示该任务正在执行中（或者处于挂起状态）
同时，还要将该描述符传送到TR寄存器的描述符高速缓存器中。

子程序load_relocate_program 里TSS相关代码(位于内核程序c15_core.asm）

TSS 与TCB 一 一对应

• 登记 TSS基地址、TSS选择子 到 TCB（这样理解，从任务A切换到任务B时，这里登记用的就是任务B的TCB，登记的内容就是任务B的 TSS基地址、TSS选择子，保证一个任务、一个TCB、一个TSS）；
• 第15章的代码，是从内核程序切换到用户程序的，那么内核程序就是任务A，用户程序就是任务B；
• 并且，内核程序是不需要TCB的；
• 如图所示，第15章的代码要分别用call 以及 jmp 各完成一次切换，同一次任务我都用相同的颜色画了TCB和TSS；

 ;创建用户程序的TSS
         mov ecx,104                        ;tss的基本尺寸
         mov [es:esi+0x12],cx              
         dec word [es:esi+0x12]             ;登记TSS界限值到TCB 
         call sys_routine_seg_sel:allocate_memory
         mov [es:esi+0x14],ecx              ;登记TSS基地址到TCB

...

  ;在GDT中登记TSS描述符
         mov eax,[es:esi+0x14]              ;TSS的起始线性地址
         movzx ebx,word [es:esi+0x12]       ;段长度（界限）
         mov ecx,0x00408900                 ;TSS描述符，特权级0
         call sys_routine_seg_sel:make_seg_descriptor
         call sys_routine_seg_sel:set_up_gdt_descriptor
         mov [es:esi+0x18],cx               ;登记TSS选择子到TCB

完整填写TSS

• 注意这里填的就是TSS的内容，不是TSS描述符；
• 根据注释以及TSS格式来一一填写即可

TSS格式 https://www.jianshu.com/p/adb70daa6d2c

        ;访问用户程序头部，获取数据填充TSS
        mov ebx,[ebp+11*4]              ;从堆栈中取得TCB的基地址
        mov edi,[es:ebx+0x06]           ;取得用户程序加载基地址
        
        mov edx,[es:edi+0x10]           ;登记程序入口点 EIP
        mov [es:ecx+32],edx             ;到TSS
        
        mov dx,[es:edi+0x14]            ;登记程序代码段 CS 选择子
        mov [es:ecx+76],dx              ;到TSS
        
        mov dx,[es:edi+0x08]            ;登记堆栈段 SS 选择子
        mov [es:ecx+80],dx

        mov dx,[es:edi+0x04]            ;登记 程序数据段 DS（指向程序头部段）
        mov word [es:ecx+84],dx 
        
        mov word [es:ecx+72],0          ;TSS中的 ES=0
        mov word [es:ecx+88],0          ;TSS中的 FS=0
        mov word [es:ecx+92],0          ;TSS中的 GS=0

        pushfd                          ;将EFLAGS寄存器的内容压入栈
        pop edx                         ;再将其弹出到EDX寄存器
        
        mov dword [es:ecx+36],edx       ;登记TSS中的EFLAGS

[如图红色文字部分]使用call指令进行任务切换(位于内核程序c15_core.asm：标号start后面)

;创建TCB 这个TCB属于即将切换去的任务
mov ecx,0x46
call sys_routine_seg_sel:allocate_memory
call append_to_tcb_link            ;将此TCB添加到TCB链中 


push dword 50                      ;用户程序位于逻辑50扇区
push ecx                           ;压入任务控制块起始线性地址 
       
call load_relocate_program          ; 会往创建属于要切换去的任务的TSS★
                                    ; 会往TCB里面填写TSS选择子★     
      
;32位间接远调用指令CALL                                 
call far [es:ecx+0x14]  ;执行任务切换
                        ;ECX指向要切换任务（用户程序）的TCB
                        ;从TCB中取出TSS基地址、TSS选择子
                        ;CPU发现这是TSS选择子，就知道要执行任务切换
                        ;新任务的TSS完整内容在子程序load_relocate_program中已经填写完毕

[如图绿色文字部分]使用jmp指令进行任务切换(位于内核程序c15_core.asm：标号start后面)

;创建TCB 这个TCB属于即将切换去的任务
mov ecx,0x46
call sys_routine_seg_sel:allocate_memory
call append_to_tcb_link            ;将此TCB添加到TCB链中 

push dword 50                      ;用户程序位于逻辑50扇区
push ecx                           ;压入任务控制块起始线性地址

call load_relocate_program          ; 会往创建属于要切换去的任务的TSS★
                                    ; 会往TCB里面填写TSS选择子★     

;32位间接远转移指令JMP
 jmp far [es:ecx+0x14]          ;执行任务切换
                              ;ECX指向要切换任务（用户程序）的TCB
                              ;从TCB中取出TSS基地址、TSS选择子
                              ;CPU发现这是TSS选择子，就知道要执行任务切换
                              ;新任务的TSS完整内容在子程序load_relocate_program中已经填写完毕